UniswapV3添加流动性数量计算 | 登链社区 | 技术问答

50 UniswapV3添加流动性数量计算

回答问题即可获得 5 贡献值，回答被采纳后即可获得 55 学分。

在使用UniswapV3添加流动性时，已知tickLower、tickUpper、当前sqrtRatioX96、预期添加的token0或者token1数量，根据这4个已知条件如何计算出对应的token1或者token0数量？ 我本来打算使用Uniswap/v3-periphery -> LiquidityAmounts.sol库来计算，结果发现好像不能满足需求。

0 条评论
分类：Uniswap

默认排序时间排序

2 个回答

Wade - Footprint Analytics CTO 3天前

　擅长：数据分析,GameFi,NFT

参考一下
```js
// SPDX-License-Identifier: MIT
pragma solidity ^0.7.6;

import '@uniswap/v3-periphery/contracts/libraries/LiquidityAmounts.sol';
import '@uniswap/v3-core/contracts/libraries/TickMath.sol';

contract UniswapV3LiquidityCalculator {
    function calculateAmounts(
        uint160 sqrtRatioX96,
        int24 tickLower,
        int24 tickUpper,
        uint256 amount0Desired,
        uint256 amount1Desired
    ) external pure returns (uint256 amount0, uint256 amount1) {
        uint160 sqrtRatioAX96 = TickMath.getSqrtRatioAtTick(tickLower);
        uint160 sqrtRatioBX96 = TickMath.getSqrtRatioAtTick(tickUpper);

uint128 liquidity;
        if (amount0Desired > 0) {
            liquidity = LiquidityAmounts.getLiquidityForAmount0(
                sqrtRatioAX96,
                sqrtRatioBX96,
                amount0Desired
            );
            amount1 = LiquidityAmounts.getAmount1ForLiquidity(
                sqrtRatioX96,
                sqrtRatioAX96,
                sqrtRatioBX96,
                liquidity
            );
        } else {
            liquidity = LiquidityAmounts.getLiquidityForAmount1(
                sqrtRatioAX96,
                sqrtRatioBX96,
                amount1Desired
            );
            amount0 = LiquidityAmounts.getAmount0ForLiquidity(
                sqrtRatioX96,
                sqrtRatioAX96,
                sqrtRatioBX96,
                liquidity
            );
        }
    }
}

```

蘭兹 21小时前

V3的添加流动性所需toke1数量是通过前端sdk计算的，位于v3-sdk/src/utils/maxLiquidityForAmounts.ts

用soldiity实现版本

pragma solidity ^0.8.0;

contract LiquidityCalculator {
        uint256 constant Q96 = 2**96;

// 计算 amount0 的最大流动性 (不精确版)
        function maxLiquidityForAmount0Imprecise(
            uint160 sqrtRatioAX96,
            uint160 sqrtRatioBX96,
            uint256 amount0
        ) public pure returns (uint256) {
            if (sqrtRatioAX96 > sqrtRatioBX96) (sqrtRatioAX96, sqrtRatioBX96) = (sqrtRatioBX96, sqrtRatioAX96);
            uint256 intermediate = (uint256(sqrtRatioAX96) * uint256(sqrtRatioBX96)) / Q96;
            return (amount0 * intermediate) / (uint256(sqrtRatioBX96) - uint256(sqrtRatioAX96));
        }

// 计算 amount0 的最大流动性 (精确版)
        function maxLiquidityForAmount0Precise(
            uint160 sqrtRatioAX96,
            uint160 sqrtRatioBX96,
            uint256 amount0
        ) public pure returns (uint256) {
            if (sqrtRatioAX96 > sqrtRatioBX96) {
                (sqrtRatioAX96, sqrtRatioBX96) = (sqrtRatioBX96, sqrtRatioAX96);
            }
            uint256 numerator = uint256(amount0) * uint256(sqrtRatioAX96) * uint256(sqrtRatioBX96);
            uint256 denominator = Q96 * (uint256(sqrtRatioBX96) - uint256(sqrtRatioAX96));
            return numerator / denominator;
        }

// 计算 amount1 的最大流动性
        function maxLiquidityForAmount1(
            uint160 sqrtRatioAX96,
            uint160 sqrtRatioBX96,
            uint256 amount1
        ) public pure returns (uint256) {
            if (sqrtRatioAX96 > sqrtRatioBX96) {
                (sqrtRatioAX96, sqrtRatioBX96) = (sqrtRatioBX96, sqrtRatioAX96);
            }
            return (amount1 * Q96) / (uint256(sqrtRatioBX96) - uint256(sqrtRatioAX96));
        }

// 根据当前价格和边界价格计算最大流动性
        function maxLiquidityForAmounts(
            uint160 sqrtRatioCurrentX96,
            uint160 sqrtRatioAX96,
            uint160 sqrtRatioBX96,
            uint256 amount0,
            uint256 amount1,
            bool useFullPrecision
        ) public pure returns (uint256) {
            if (sqrtRatioAX96 > sqrtRatioBX96) {
                (sqrtRatioAX96, sqrtRatioBX96) = (sqrtRatioBX96, sqrtRatioAX96);
            }

if (sqrtRatioCurrentX96 <= sqrtRatioAX96) {
                return useFullPrecision
                ? maxLiquidityForAmount0Precise(sqrtRatioAX96, sqrtRatioBX96, amount0)
                : maxLiquidityForAmount0Imprecise(sqrtRatioAX96, sqrtRatioBX96, amount0);
            } else if (sqrtRatioCurrentX96 < sqrtRatioBX96) {
                uint256 liquidity0 = useFullPrecision
                ? maxLiquidityForAmount0Precise(sqrtRatioCurrentX96, sqrtRatioBX96, amount0)
                : maxLiquidityForAmount0Imprecise(sqrtRatioCurrentX96, sqrtRatioBX96, amount0);
                uint256 liquidity1 = maxLiquidityForAmount1(sqrtRatioAX96, sqrtRatioCurrentX96, amount1);
                return liquidity0 < liquidity1 ? liquidity0 : liquidity1;
            } else {
                return maxLiquidityForAmount1(sqrtRatioAX96, sqrtRatioBX96, amount1);
            }
        }

function maxLiquidityFormAmount0(
            uint160 sqrtRatioCurrentX96,
            uint160 sqrtRatioAX96,
            uint160 sqrtRatioBX96,
            uint256 amount0,
            bool useFullPrecision
        ) public pure returns (uint256) {
            return maxLiquidityForAmounts(sqrtRatioCurrentX96, sqrtRatioAX96, sqrtRatioBX96, amount0, type(uint256).max, useFullPrecision);
        }

function maxLiquidityFormAmount1(
            uint160 sqrtRatioCurrentX96,
            uint160 sqrtRatioAX96,
            uint160 sqrtRatioBX96,
            uint256 amount1,
            bool useFullPrecision
        ) public pure returns (uint256) {
            return maxLiquidityForAmounts(sqrtRatioCurrentX96, sqrtRatioAX96, sqrtRatioBX96, type(uint256).max, amount1, useFullPrecision);
        }
    }

调用maxLiquidityFormAmount0计算能提供的最大流动性，其中useFullPrecision为true。（solidity计算可能会导致溢出，可以参考ts代码计算）

得到最大流动性数量后，再调用calcAmount1fromLiquidity计算所需amount1数量。

function calcAmount1fromLiquidity(
        uint160 sqrtRatioCurrentX96,
        uint160 sqrtRatioAX96,
        uint160 sqrtRatioBX96,
        uint128 liquidity
    ) public pure returns (uint256 amount0) {
        if (sqrtRatioAX96 > sqrtRatioBX96) {
            (sqrtRatioAX96, sqrtRatioBX96) = (sqrtRatioBX96, sqrtRatioAX96);
        }

if (sqrtRatioCurrentX96 <= sqrtRatioAX96) {
            return 0;
        } else if (sqrtRatioCurrentX96 < sqrtRatioBX96) {
            return SqrtPriceMath.getAmount1Delta(sqrtRatioAX96, sqrtRatioCurrentX96, liquidity, false);
        } else {
            return SqrtPriceMath.getAmount1Delta(sqrtRatioAX96, sqrtRatioBX96, liquidity, false);
        }
    }

实际操作例子：
a、假设token0-token1-0.3%的pair，传入token0数量为1000000000000000，添加流动性价格区间为tickLower：104040（14386876850931674113169112377587），tickUpper：104100（14430100122848938449791809866234），当前价格sqrtPrice：14391912887286834113868107134558，计算得到流动性数量为68642021049326277000
b、再根据流动性数量68642021049326277000，当前价格及添加流动性价格区间，通过getAmount1Delta计算实际所需tokenB数量4363141874378669603，此时再按照tokenA（1000000000000000）、tokenB（4363141874378669603）数量计算流动性数量，则得到最终添加的实际流动性数量为68642021049326276985。

实际调用结果：

![image.png](https://img.learnblockchain.cn/attachments/2024/06/7PHr4WE96681582e34f10.png)

2 关注
0 收藏，190 浏览
juzi 提出于 3天前