ERC-1616: 属性注册表标准

/**
 * @title EIP-1616 属性注册表标准接口。EIP-165 ID: 0x5f46473f
 */
interface AttributeRegistryInterface {
  function hasAttribute(address account, uint256 attributeTypeID) external view returns (bool);
  function getAttributeValue(address account, uint256 attributeTypeID) external view returns (uint256);
  function countAttributeTypes() external view returns (uint256);
  function getAttributeTypeID(uint256 index) external view returns (uint256);
}

/**
 * @title EIP-165 接口。EIP-165 ID: 0x01ffc9a7
 */
interface EIP-165 {
  /**
   * @notice EIP-165 支持. 属性注册表接口 ID 为 0x5f46473f.
   * @param _interfaceID 接口标识符，如 EIP-165 中指定
   * @return 对于 0x01ffc9a7 & 0x5f46473f 返回 True，对于不支持的接口返回 false。
   */
  function supportsInterface(bytes4 _interfaceID) external view returns (bool);
}

function hasAttribute(address account, uint256 attributeTypeID) external view returns (bool)

function getAttributeValue(address account, uint256 attributeTypeID) external view returns (uint256)

function countAttributeTypes() external view returns (uint256)

function getAttributeTypeID(uint256 index) external view returns (uint256)

pragma solidity ^0.4.25;

/**
 * @title 属性注册表接口。EIP-165 ID: 0x5f46473f
 */
interface AttributeRegistryInterface {
  /**
   * @notice 检查是否已将 ID 为 `attributeTypeID` 的类型的属性分配给
   *  `account` 的帐户，并且当前是否有效。
   * @param account address 要检查是否存在有效属性的帐户。
   * @param attributeTypeID uint256 要检查的属性类型的 ID。
   * @return 如果属性已分配且有效，则为 True，否则为 false。
   * @dev 此函数必须返回 true 或 false - 即调用此
   * 函数不得导致调用者 revert。
   */
  function hasAttribute(
    address account,
    uint256 attributeTypeID
  ) external view returns (bool);

  /**
   * @notice 检索 ID 为 `attributeTypeID` 的类型的属性在
   * `account` 的帐户上的值，假设它有效。
   * @param account address 要检查给定属性值的帐户。
   * @param attributeTypeID uint256 要检查的属性类型的 ID。
   * @return 如果属性有效，则为属性值，否则 revert。
   * @dev 如果直接先前或后续
   * 使用相同的 `account` 和
   * `attributeTypeID` 参数调用 `hasAttribute` 函数将返回 false，则此函数必须 revert。
   */
  function getAttributeValue(
    address account,
    uint256 attributeTypeID
  ) external view returns (uint256);

  /**
   * @notice 计算注册表定义的属性类型的数量。
   * @return 可用属性类型的数量。
   * @dev 此函数必须返回一个正整数值 - 即调用
   * 此函数不得导致调用者 revert。
   */
  function countAttributeTypes() external view returns (uint256);

  /**
   * @notice 获取索引 `index` 处的属性类型的 ID。
   * @param index uint256 有问题的属性类型的索引。
   * @return 属性类型的 ID。
   * @dev 如果提供的 `index` 值落在直接先前或后续
   * 调用 `countAttributeTypes` 函数返回的值范围之外，则此函数必须 revert。如果提供的
   *  `index` 值落在上述范围内，则不得 revert。
   */
  function getAttributeTypeID(uint256 index) external view returns (uint256);
}


/**
 * @title Attribute Registry 实现的一个简单示例。
 */
contract AttributeRegistry is AttributeRegistryInterface {
  // 此特定实现仅定义两种属性类型。
  enum Affiliation { Whitehat, Blackhat }

  // 有关静态数组中保存的属性类型的顶级信息。
  uint256[2] private _attributeTypeIDs;

  // 静态数组中跟踪的当前颁发的属性数量。
  uint256[2] private _issuedAttributeCounters;

  // 嵌套映射中按帐户和属性类型保存的已颁发属性。
  mapping(address => mapping(uint256 => bool)) private _issuedAttributes;

  // 嵌套映射中按帐户和类型保存的颁发属性值。
  mapping(address => mapping(uint256 => uint256)) private _issuedAttributeValues;

  /**
  * @notice 构造函数，定义此特定注册表上可用的两种属性类型。
  */
  constructor() public {
    // 设置 whitehat (8008) 和 blackhat (1337) 的属性类型 ID。
    _attributeTypeIDs = [8008, 1337];
  }

  /**
   * @notice 将“whitehat”属性类型分配给 `msg.sender`。
   * @dev 该函数可能无法被已分配有“blackhat”属性类型的帐户调用。
   * 这个函数是任意的，不是
   * 属性注册表规范的一部分。
   */
  function joinWhitehats() external {
    // 获取属性注册表上 blackhat 属性类型的索引。
    uint256 blackhatIndex = uint256(Affiliation.Blackhat);

    // 获取 blackhat 属性类型的属性类型 ID。
    uint256 blackhatAttributeTypeID = _attributeTypeIDs[blackhatIndex];

    // 如果已设置 blackhat，则不允许设置 whitehat 属性。
    require(
      !_issuedAttributes[msg.sender][blackhatAttributeTypeID],
      "不允许 blackhat！"
    );

    // 获取属性注册表上 whitehat 属性类型的索引。
    uint256 whitehatIndex = uint256(Affiliation.Whitehat);

    // 获取 whitehat 属性类型的属性类型 ID。
    uint256 whitehatAttributeTypeID = _attributeTypeIDs[whitehatIndex];

    // 将该属性标记为已在给定地址上颁发。
    _issuedAttributes[msg.sender][whitehatAttributeTypeID] = true;

    // 计算 whitehat 属性的总数的新数量。
    uint256 incrementCounter = _issuedAttributeCounters[whitehatIndex] + 1;

    // 将属性值设置为新分配的 whitehat 属性的总数。
    _issuedAttributeValues[msg.sender][whitehatAttributeTypeID] = incrementCounter;

    // 更新 whitehat 属性总数的计数器的值。
    _issuedAttributeCounters[whitehatIndex] = incrementCounter;
  }

  /**
   * @notice 将“blackhat”属性类型分配给 `msg.sender`。
   * @dev 该函数可以被任何帐户调用，但分配的“whitehat”
   * 属性将被删除。这个函数是任意的，不是
   * 属性注册表规范的一部分。
   */
  function joinBlackhats() external {
    // 获取属性注册表上 blackhat 属性类型的索引。
    uint256 blackhatIndex = uint256(Affiliation.Blackhat);

    // 获取 blackhat 属性类型的属性类型 ID。
    uint256 blackhatAttributeTypeID = _attributeTypeIDs[blackhatIndex];

    // 将该属性标记为已在给定地址上颁发。
    _issuedAttributes[msg.sender][blackhatAttributeTypeID] = true;

    // 计算 blackhat 属性的总数的新数量。
    uint256 incrementCounter = _issuedAttributeCounters[blackhatIndex] + 1;

    // 将属性值设置为新分配的 blackhat 属性的总数。
    _issuedAttributeValues[msg.sender][blackhatAttributeTypeID] = incrementCounter;

    // 更新 blackhat 属性总数的计数器的值。
    _issuedAttributeCounters[blackhatIndex] = incrementCounter;

    // 获取属性注册表上 whitehat 属性类型的索引。
    uint256 whitehatIndex = uint256(Affiliation.Whitehat);

    // 获取 whitehat 属性类型的属性类型 ID。
    uint256 whitehatAttributeTypeID = _attributeTypeIDs[whitehatIndex];

    // 确定是否已分配 whitehat 属性类型。
    if (_issuedAttributes[msg.sender][whitehatAttributeTypeID]) {
      // 如果是，则删除该属性。
      delete _issuedAttributes[msg.sender][whitehatAttributeTypeID];

      // 同时也删除属性值。
      delete _issuedAttributeValues[msg.sender][whitehatAttributeTypeID];

      // 将属性值设置为新分配的 whitehat 属性的总数。
      uint256 decrementCounter = _issuedAttributeCounters[whitehatIndex] - 1;

      // 更新 whitehat 属性总数的计数器的值。
      _issuedAttributeCounters[whitehatIndex] = decrementCounter;
    }
  }

  /**
   * @notice 获取分配的 whitehat 和 blackhat 属性的总数。
   * @return 包含分配的 whitehat 和 blackhat 属性计数的数组。
   * @dev 这个函数是任意的，不是属性注册表
   * 规范的一部分。
   */
  function totalHats() external view returns (uint256[2]) {
    // 返回包含计数器值的数组。
    return _issuedAttributeCounters;
  }

  /**
   * @notice 检查是否已将 ID 为 `attributeTypeID` 的类型的属性分配给
   *  `account` 的帐户，并且当前是否有效。
   * @param account address 要检查是否存在有效属性的帐户。
   * @param attributeTypeID uint256 要检查的属性类型的 ID。
   * @return 如果属性已分配且有效，则为 True，否则为 false。
   * @dev 此函数必须返回 true 或 false - 即调用此
   * 函数不得导致调用者 revert。
   */
  function hasAttribute(
    address account,
    uint256 attributeTypeID
  ) external view returns (bool) {
    // 按帐户和属性类型 ID 返回属性的分配状态
    return _issuedAttributes[account][attributeTypeID];
  }

  /**
   * @notice 检索 ID 为 `attributeTypeID` 的类型的属性在
   * `account` 的帐户上的值，假设它有效。
   * @param account address 要检查给定属性值的帐户。
   * @param attributeTypeID uint256 要检查的属性类型的 ID。
   * @return 如果属性有效，则为属性值，否则 revert。
   * @dev 如果直接先前或后续
   * 使用相同的 `account` 和
   * `attributeTypeID` 参数调用 `hasAttribute` 函数将返回 false，则此函数必须 revert。
   */
  function getAttributeValue(
    address account,
    uint256 attributeTypeID
  ) external view returns (uint256 value) {
    // 如果未分配具有给定帐户和属性类型 ID 的属性，则还原
    require(
      _issuedAttributes[account][attributeTypeID],
      "找不到具有提供的帐户和属性类型 ID 的值"
    );

    // 返回属性值。
    return _issuedAttributeValues[account][attributeTypeID];
  }

  /**
   * @notice 计算注册表定义的属性类型的数量。
   * @return 可用属性类型的数量。
   * @dev 此函数必须返回一个正整数值 - 即调用
   * 此函数不得导致调用者 revert。
   */
  function countAttributeTypes() external view returns (uint256) {
    // 返回属性类型 ID 数组的长度。
    return _attributeTypeIDs.length;
  }

  /**
   * @notice 获取索引 `index` 处的属性类型的 ID。
   * @param index uint256 有问题的属性类型的索引。
   * @return 属性类型的 ID。
   * @dev 如果提供的 `index` 值落在直接先前或后续
   * 调用 `countAttributeTypes` 函数返回的值范围之外，则此函数必须 revert。如果提供的
   *  `index` 值落在上述范围内，则不得 revert。
   */
  function getAttributeTypeID(uint256 index) external view returns (uint256) {
    // 如果提供的索引超出范围，则还原。
    require(
      index < _attributeTypeIDs.length,
      "提供的索引超出了定义的属性类型 ID 的范围"
    );

    // 返回数组中给定索引处的属性类型 ID。
    return _attributeTypeIDs[index];
  }
}