ERC-3000: 乐观执行治理标准

library ERC3000Data {
    struct Container {
        Payload payload;
        Config config;
    }

    struct Payload {
        uint256 nonce;
        uint256 executionTime;
        address submitter;
        IERC3000Executor executor;
        Action[] actions;
        bytes proof;
    }

    struct Action {
        address to;
        uint256 value;
        bytes data;
    }

    struct Config {
        uint256 executionDelay;
        Collateral scheduleDeposit;
        Collateral challengeDeposit;
        Collateral vetoDeposit;
        address resolver;
        bytes rules;
    }

    struct Collateral {
        address token;
        uint256 amount;
    }
}

abstract contract IERC3000 {
    /**
     * @notice 安排一个操作以供执行，允许在定义的时间窗口内进行挑战和否决
     * @param container 一个 Container 结构体，包含计划执行的 paylaod 和
       系统的当前配置
     */
    function schedule(ERC3000Data.Container memory container) virtual public returns (bytes32 containerHash);
    event Scheduled(bytes32 indexed containerHash, ERC3000Data.Payload payload, ERC3000Data.Collateral collateral);

    /**
     * @notice 在其执行延迟过去后执行一个操作，并且其状态未被挑战或否决修改
     * @param container 一个 ERC3000Data.Container 结构体，包含计划执行的 paylaod 和
       系统的当前配置
     * 应该是 MUST payload.executor.exec(payload.actions)
     */
    function execute(ERC3000Data.Container memory container) virtual public returns (bytes[] memory execResults);
    event Executed(bytes32 indexed containerHash, address indexed actor, bytes[] execResults);

    /**
     * @notice 如果容器的调度根据 Config.rules 是非法的，则挑战容器。将抵押品和争议费用从发送者提取到合约中
     * @param container 一个 ERC3000Data.Container 结构体，包含计划执行的 paylaod 和
       系统的当前配置
     * @param reason 提示案例审查员为什么计划的容器是非法的
     */
    function challenge(ERC3000Data.Container memory container, bytes memory reason) virtual public returns (uint256 resolverId);
    event Challenged(bytes32 indexed containerHash, address indexed actor, bytes reason, uint256 resolverId, ERC3000Data.Collateral collateral);

    /**
     * @notice 一旦仲裁员做出最终裁决，就可以对挑战应用仲裁员的裁决
     * @param container 一个 ERC3000Data.Container 结构体，包含计划执行的 paylaod 和
       系统的当前配置
     * @param resolverId 仲裁员中创建的container争议中的 disputeId
     */
    function resolve(ERC3000Data.Container memory container, uint256 resolverId) virtual public returns (bytes[] memory execResults);
    event Resolved(bytes32 indexed containerHash, address indexed actor, bool approved);

    /**
     * @dev 可选
     * @notice 一旦仲裁员做出最终裁决，就可以对挑战应用仲裁员的裁决
     * @param payloadHash 被否决的 payload 的哈希值
     * @param config 一个 ERC3000Data.Config 结构体，它保存附加到被否决的 payload 的配置
     */
    function veto(bytes32 payloadHash, ERC3000Data.Config memory config, bytes memory reason) virtual public;
    event Vetoed(bytes32 indexed containerHash, address indexed actor, bytes reason, ERC3000Data.Collateral collateral);

    /**
     * @dev 可选：实现者可以选择不实现（必须发出初始的 Configured 事件）
     * @notice 为所有*新的* 计划容器应用新的配置
     * @param config 一个 ERC3000Data.Config 结构体，包含将控制队列的所有新参数
     */
    function configure(ERC3000Data.Config memory config) virtual public returns (bytes32 configHash);
    event Configured(bytes32 indexed containerHash, address indexed actor, ERC3000Data.Config config);
}