ERC-4931: 通用代币升级标准

interface IEIP4931 {

/// @dev 用于确定要从哪个合约升级的 getter（“源合约”）
/// @return 源代币合约的地址
function upgradeSource() external view returns(address)

/// @dev 用于确定要升级到哪个合约的 getter（“目标合约”）
/// @return 目标代币合约的地址
function upgradeDestination() external view returns(address)

/// @dev 此方法在合约提供升级时返回 true，否则返回 false
/// @return 升级状态，布尔值
function isUpgradeActive() external view returns(bool)

/// @dev 此方法在合约提供降级时返回 true，否则返回 false
/// @return 降级状态，布尔值
function isDowngradeActive() external view returns(bool)

/// @dev 用于获取进行升级时收到的目标代币与源代币的比率的 getter
/// @return 两个 uint256，第一个表示分子，第二个表示在升级期间分配的目标代币与源代币的比率的分母
function ratio() external view returns(uint256, uint256)

/// @dev 用于获取已升级为目标代币的源代币总量的 getter。
/// 如果实现了降级可选扩展，则该值可能不会严格增加。
/// @return 已升级为目标代币的源代币数量
function totalUpgraded() external view returns(uint256)

/// @dev 一种模拟升级调用的方法，用于确定从升级收到的目标代币数量
/// 以及作为余数剩余的源代币数量
/// @param sourceAmount 将要升级的源代币数量
/// @return destinationAmount 一个 uint256，表示如果调用升级收到的目标代币数量
/// @return sourceRemainder 一个 uint256，表示如果调用升级剩余的源代币数量
function computeUpgrade(uint256 sourceAmount) external view
        returns (uint256 destinationAmount, uint256 sourceRemainder)

/// @dev 一种模拟降级调用的方法，用于确定从降级收到的源代币数量
/// 以及作为余数剩余的目标代币数量
/// @param destinationAmount 将要降级的目标代币数量
/// @return sourceAmount 一个 uint256，表示如果调用降级收到的源代币数量
/// @return destinationRemainder 一个 uint256，表示如果调用升级剩余的目标代币数量
function computeDowngrade(uint256 destinationAmount) external view
        returns (uint256 sourceAmount, uint256 destinationRemainder)

/// @dev 一种从源代币升级到目标代币的方法。
/// 如果升级状态不为 true，如果未在源合约上调用 approve，或者如果 sourceAmount 大于 msg.sender 地址的源代币数量，则调用将失败。
/// 如果比率会导致代币数量因舍入/截断而被销毁，则升级调用将仅升级最接近的源代币的整数数量，从而将多余的数量返回到 msg.sender 地址。
/// 发出 Upgrade 事件
/// @param _to 目标代币在升级完成后将发送到的地址
/// @param sourceAmount 将要升级的源代币数量
function upgrade(address _to, uint256 sourceAmount) external

/// @dev 一种从目标代币降级为源代币的方法。
/// 如果降级状态不为 true，如果未在目标合约上调用 approve，或者如果 destinationAmount 大于 msg.sender 地址的目标代币数量，则调用将失败。
/// 如果比率会导致代币数量因舍入/截断而被销毁，则降级调用将仅降级最接近的目标代币的整数数量，从而将多余的数量返回到 msg.sender 地址。
///  发出 Downgrade 事件
/// @param _to 源代币在降级完成后将发送到的地址
/// @param destinationAmount 将要降级的目标代币数量
function downgrade(address _to, uint256 destinationAmount) external

/// @param _from 调用升级的地址
/// @param _to 升级完成后目标代币发送到的地址
/// @param sourceAmount 已升级的源代币数量
/// @param destinationAmount 发送到 _to 地址的目标代币数量
event Upgrade(address indexed _from, address indexed _to, uint256 sourceAmount, uint256 destinationAmount)

/// @param _from 调用降级的地址
/// @param _to 源代币发送到的地址
/// @param sourceAmount 发送到 _to 地址的源代币数量
/// @param destinationAmount 已降级的目标代币数量
event Downgrade(address indexed _from, address indexed _to, uint256 sourceAmount, uint256 destinationAmount)
}

//SPDX-License-Identifier: Apache-2.0
pragma solidity 0.8.9;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "./IEIP4931.sol";

contract SourceUpgrade is  IEIP4931 {
	using SafeERC20  for IERC20;

	uint256 constant RATIO_SCALE = 10**18;
    
	IERC20 private source;
	IERC20 private destination;
	bool private upgradeStatus;
	bool private downgradeStatus;
	uint256 private numeratorRatio;
	uint256 private denominatorRatio;
	uint256 private sourceUpgradedTotal;

	mapping(address => uint256) public upgradedBalance;

	constructor(address _source, address _destination, bool _upgradeStatus, bool _downgradeStatus, uint256 _numeratorRatio, uint256 _denominatorRatio) {
		require(_source != _destination, "SourceUpgrade: source and destination addresses are the same");
		require(_source != address(0), "SourceUpgrade: source address cannot be zero address");
		require(_destination != address(0), "SourceUpgrade: destination address cannot be zero address");
		require(_numeratorRatio > 0, "SourceUpgrade: numerator of ratio cannot be zero");
		require(_denominatorRatio > 0, "SourceUpgrade: denominator of ratio cannot be zero");

		source = IERC20(_source);
		destination = IERC20(_destination);
		upgradeStatus = _upgradeStatus;
		downgradeStatus = _downgradeStatus;
		numeratorRatio = _numeratorRatio;
		denominatorRatio = _denominatorRatio;
	}

	/// @dev 用于确定要从哪个合约升级的 getter（“源合约”）
	/// @return 源代币合约的地址
	function upgradeSource() external view returns(address) {
		return address(source);
	}

	/// @dev 用于确定要升级到哪个合约的 getter（“目标合约”）
	/// @return 目标代币合约的地址
	function upgradeDestination() external view returns(address) {
		return address(destination);
	}

	/// @dev 此方法在合约提供升级时返回 true，否则返回 false
	/// @return 升级状态，布尔值
	function isUpgradeActive() external view returns(bool) {
		return upgradeStatus;
	}

	/// @dev 此方法在合约提供降级时返回 true，否则返回 false
	/// @return 降级状态，布尔值
	function isDowngradeActive() external view returns(bool) {
		return downgradeStatus;
	}

	/// @dev 用于获取进行升级时收到的目标代币与源代币的比率的 getter
	/// @return 两个 uint256，第一个表示分子，第二个表示在升级期间分配的目标代币与源代币的比率的分母
	function ratio() external view returns(uint256, uint256) {
		return (numeratorRatio, denominatorRatio);
	}

	/// @dev 用于获取已升级为目标代币的源代币总量的 getter。
	/// 如果实现了降级可选扩展，则该值可能不会严格增加。
	/// @return 已升级为目标代币的源代币数量
	function totalUpgraded() external view returns(uint256) {
		return sourceUpgradedTotal;
	}

	/// @dev 一种模拟升级调用的方法，用于确定从升级收到的目标代币数量
	/// 以及作为余数剩余的源代币数量
	/// @param sourceAmount 将要升级的源代币数量
	/// @return destinationAmount 一个 uint256，表示如果调用升级收到的目标代币数量
	/// @return sourceRemainder 一个 uint256，表示如果调用升级剩余的源代币数量
	function computeUpgrade(uint256 sourceAmount)
		public
		view
		returns (uint256 destinationAmount, uint256 sourceRemainder)
	{
		sourceRemainder = sourceAmount % (numeratorRatio / denominatorRatio);
		uint256 upgradeableAmount = sourceAmount - (sourceRemainder * RATIO_SCALE);
		destinationAmount = upgradeableAmount * (numeratorRatio / denominatorRatio);
	}

	/// @dev 一种模拟降级调用的方法，用于确定从降级收到的源代币数量
	/// 以及作为余数剩余的目标代币数量
	/// @param destinationAmount 将要降级的目标代币数量
	/// @return sourceAmount 一个 uint256，表示如果调用降级收到的源代币数量
	/// @return destinationRemainder 一个 uint256，表示如果调用升级剩余的目标代币数量
	function computeDowngrade(uint256 destinationAmount)
		public
		view
		returns (uint256 sourceAmount, uint256 destinationRemainder)
	{
		destinationRemainder = destinationAmount % (denominatorRatio / numeratorRatio);
		uint256 upgradeableAmount = destinationAmount - (destinationRemainder * RATIO_SCALE);
		sourceAmount = upgradeableAmount / (denominatorRatio / numeratorRatio);
	}

	/// @dev 一种从源代币升级到目标代币的方法。
	/// 如果升级状态不为 true，如果未在源合约上调用 approve，或者如果 sourceAmount 大于 msg.sender 地址的源代币数量，则调用将失败。
	/// 如果比率会导致代币数量因舍入/截断而被销毁，则升级调用将仅升级最接近的源代币的整数数量，从而将多余的数量返回到 msg.sender 地址。
	/// 发出 Upgrade 事件
	/// @param _to 目标代币在升级完成后将发送到的地址
	/// @param sourceAmount 将要升级的源代币数量
	function upgrade(address _to, uint256 sourceAmount) external {
		require(upgradeStatus == true, "SourceUpgrade: upgrade status is not active");
		(uint256 destinationAmount, uint256 sourceRemainder) = computeUpgrade(sourceAmount);
		sourceAmount -= sourceRemainder;
		require(sourceAmount > 0, "SourceUpgrade: disallow conversions of zero value");

		upgradedBalance[msg.sender] += sourceAmount;
		source.safeTransferFrom(
			msg.sender,
			address(this),
			sourceAmount
			);
		destination.safeTransfer(_to, destinationAmount);
		sourceUpgradedTotal += sourceAmount;
		emit Upgrade(msg.sender, _to, sourceAmount, destinationAmount);
	}

	/// @dev 一种从目标代币降级为源代币的方法。
	/// 如果降级状态不为 true，如果未在目标合约上调用 approve，或者如果 destinationAmount 大于 msg.sender 地址的目标代币数量，则调用将失败。
	/// 如果比率会导致代币数量因舍入/截断而被销毁，则降级调用将仅降级最接近的目标代币的整数数量，从而将多余的数量返回到 msg.sender 地址。
	///  发出 Downgrade 事件
	/// @param _to 源代币在降级完成后将发送到的地址
	/// @param destinationAmount 将要降级的目标代币数量
	function downgrade(address _to, uint256 destinationAmount) external {
		require(upgradeStatus == true, "SourceUpgrade: upgrade status is not active");
		(uint256 sourceAmount, uint256 destinationRemainder) = computeDowngrade(destinationAmount);
		destinationAmount -= destinationRemainder;
		require(destinationAmount > 0, "SourceUpgrade: disallow conversions of zero value");
		require(upgradedBalance[msg.sender] >= sourceAmount,
			"SourceUpgrade: can not downgrade more than previously upgraded"
			);

		upgradedBalance[msg.sender] -= sourceAmount;
		destination.safeTransferFrom(
			msg.sender,
			address(this),
			destinationAmount
			);
		source.safeTransfer(_to, sourceAmount);
		sourceUpgradedTotal -= sourceAmount;
		emit Downgrade(msg.sender, _to, sourceAmount, destinationAmount);
	}
}