ERC-4973: 账户绑定 Token

// SPDX-License-Identifier: CC0-1.0
pragma solidity ^0.8.6;

/// @title 账户绑定 Token
/// @dev 请参阅 https://eips.ethereum.org/EIPS/eip-4973
/// 注意：此接口的 ERC-165 标识符为 0xeb72bb7c
interface IERC4973 {
  /// @dev 当任何 ABT 的所有权通过任何机制发生变化时，都会发出此事件。
  ///  当 ABT 被给予或装备和卸下时，会发出此事件
  ///  (`to` == 0)。
  event Transfer(
    address indexed from, address indexed to, uint256 indexed tokenId
  );

  /// @notice 计算分配给所有者的所有 ABT
  /// @dev 分配给零地址的 ABT 被认为是无效的，并且此
  ///  函数会抛出关于零地址的查询。
  /// @param owner 要查询余额的地址
  /// @return `address owner` 拥有的 ABT 数量，可能为零
  function balanceOf(address owner) external view returns (uint256);

  /// @notice 查找绑定到 ERC4973 账户绑定 Token 的地址
  /// @dev 分配给零地址的 ABT 被认为是无效的，并且关于它们的查询
  ///  会抛出异常。
  /// @param tokenId ABT 的标识符。
  /// @return 绑定到 ABT 的所有者的地址。
  function ownerOf(uint256 tokenId) external view returns (address);

  /// @notice 从账户中移除 `uint256 tokenId`。在任何时候，一个
  ///  ABT 接收者必须能够通过调用此函数公开地将自己与 ABT 解除关联。
  ///  在成功执行此函数后，给定调用 `function give` 或
  ///  `function take` 的参数，Token 必须是可重新装备的。
  /// @dev 必须发出一个 `event Transfer`，其中 `address to` 字段指向
  ///  零地址。
  /// @param tokenId ABT 的标识符。
  function unequip(uint256 tokenId) external;

  /// @notice 创建 ABT 并将 ABT 的所有权从
  ///  交易的 `msg.sender` 转移到 `address to`。
  /// @dev 除非 `bytes signature` 表示
  //   EIP-712 结构化数据哈希的签名
  ///  `Agreement(address active,address passive,bytes metadata)` 表达
  ///  `address to` 明确同意公开地与 `msg.sender` 和 `bytes metadata` 相关联，否则将抛出异常。独特的 `uint256 tokenId` 必须是
  ///  通过将 `bytes32` EIP-712 结构化数据哈希类型转换为一个
  ///  `uint256` 来生成。如果 `bytes signature` 为空或 `address to` 是一个合约，
  ///  必须对 `address to` 进行与 EIP-1271 兼容的 `function isValidSignatureNow(...)` 调用。成功的执行必须导致
  ///  `event Transfer(msg.sender, to, tokenId)` 的发出。一旦 ABT 作为
  ///  合约中的 `uint256 tokenId` 存在，`function give(...)` 必须抛出异常。
  /// @param to ABT 的接收者。
  /// @param metadata 将与 ABT 关联的元数据。
  /// @param signature EIP-712 结构化数据哈希的签名
  ///  `Agreement(address active,address passive,bytes metadata)` 由
  ///  `address to` 签名。
  /// @return 通过将 `bytes32`
  ///  EIP-712 结构化数据哈希类型转换为 `uint256` 生成的唯一 `uint256 tokenId`。
  function give(address to, bytes calldata metadata, bytes calldata signature)
    external
    returns (uint256);

  /// @notice 创建 ABT 并将 ABT 的所有权从一个
  /// `address from` 转移到交易的 `msg.sender`。
  /// @dev 除非 `bytes signature` 表示
  ///  EIP-712 结构化数据哈希的签名
  ///  `Agreement(address active,address passive,bytes metadata)` 表达
  ///  `address from` 明确同意公开地与 `msg.sender` 和 `bytes metadata` 相关联，否则将抛出异常。独特的一个 `uint256 tokenId` 必须是
  ///  通过将 `bytes32` EIP-712 结构化数据哈希类型转换为一个
  ///  `uint256` 来生成。如果 `bytes signature` 为空或 `address from` 是一个合约，
  ///  必须对 `address from` 进行与 EIP-1271 兼容的 `function isValidSignatureNow(...)` 调用。成功的执行必须导致
  ///  `event Transfer(from, msg.sender, tokenId)` 的发出。一旦 ABT
  ///  作为合约中的 `uint256 tokenId` 存在，`function take(...)` 必须
  ///  抛出异常。
  /// @param from ABT 的来源。
  /// @param metadata 将与 ABT 关联的元数据。
  /// @param signature EIP-712 结构化数据哈希的签名
  ///  `Agreement(address active,address passive,bytes metadata)` 由
  ///  `address from` 签名。

  /// @return 通过将 `bytes32`
  ///  EIP-712 结构化数据哈希类型转换为 `uint256` 生成的唯一 `uint256 tokenId`。
  function take(address from, bytes calldata metadata, bytes calldata signature)
    external
    returns (uint256);

  /// @notice 将 ABT 的不透明元数据字节串解码为 Token
  ///  URI，一旦它在链上创建，它将与之关联。
  /// @param metadata 将与 ABT 关联的元数据。
  /// @return 表示元数据的 URI。
  function decodeURI(bytes calldata metadata) external returns (string memory);
}

bytes32 r = 0x68a020a209d3d56c46f38cc50a33f704f4a9a10a59377f8dd762ac66910e9b90;
bytes32 s = 0x7e865ad05c4035ab5792787d4a0297a43617ae897930a6fe4d822b8faea52064;
uint8 v   = 27;
bytes memory signature = abi.encodePacked(r, s, v);