ERC-5006: 租赁 NFT，NFT 用户扩展

// SPDX-License-Identifier: CC0-1.0

pragma solidity ^0.8.0;

interface IERC5006 {
    struct UserRecord {
        uint256 tokenId;
        address owner;
        uint64 amount;
        address user;
        uint64 expiry;
    }
    
    /**
     * @dev 当 `user` 被授予使用 `owner` 拥有的 `tokenId` 的 `amount` 数量的代币的权限时触发，
     * 权限截止日期为 `expiry`。
     */
    event CreateUserRecord(
        uint256 recordId,
        uint256 tokenId,
        uint64  amount,
        address owner,
        address user,
        uint64  expiry
    );

    /**
     * @dev 当 `recordId` 的记录被删除时触发。
     */
    event DeleteUserRecord(uint256 recordId);

    /**
     * @dev 返回 `account` 可以使用的 `tokenId` 代币数量。
     */
    function usableBalanceOf(address account, uint256 tokenId)
        external
        view
        returns (uint256);

    /**
     * @dev 返回 `account` 冻结的 `id` 类型代币数量。
     */
    function frozenBalanceOf(address account, uint256 tokenId)
        external
        view
        returns (uint256);

    /**
     * @dev 返回 `recordId` 的 `UserRecord`。
     */
    function userRecordOf(uint256 recordId)
        external
        view
        returns (UserRecord memory);

    /**
     * @dev 授予 `user` 权限以使用 `amount` 数量的 `tokenId` 代币，该代币由 `owner` 拥有，直至 `expiry`。
     *
     * 触发 {CreateUserRecord} 事件。
     *
     * 要求：
     *
     * - 如果调用者不是 `owner`，则必须已获批准通过 {setApprovalForAll} 花费 ``owner`` 的代币。
     * - `owner` 必须拥有至少 `amount` 数量的 `id` 类型代币余额。
     * - `user` 不能是零地址。
     * - `amount` 必须大于 0。
     * - `expiry` 必须在区块时间戳之后。
     */
    function createUserRecord(
        address owner,
        address user,
        uint256 tokenId,
        uint64 amount,
        uint64 expiry
    ) external returns (uint256);

    /**
     * @dev 通过调用者原子地删除 `recordId` 的 `record`。
     *
     * 触发 {DeleteUserRecord} 事件。
     *
     * 要求：
     *
     * - 调用者必须具有 allowance。
     */
    function deleteUserRecord(uint256 recordId) external;
}