ERC-5646: 令牌状态指纹

pragma solidity ^0.8.0;

interface ERC5646 is ERC165 {

    /// @notice 用于返回当前令牌状态指纹的函数。
    /// @param tokenId 所查询的令牌状态的ID。
    /// @return 当前令牌状态指纹。
    function getStateFingerprint(uint256 tokenId) external view returns (bytes32);

}

pragma solidity ^0.8.0;

/// @title 实现状态指纹的可变令牌示例。
contract LPToken is ERC721, ERC5646 {

    /// @dev 存储的令牌状态（令牌 ID => 状态）。
    mapping (uint256 => State) internal states;

    struct State {
        address asset1;
        address asset2;
        uint256 amount1;
        uint256 amount2;
        uint256 fee; // 不可变的
        address operator; // 不可变的
        uint256 expiration; // 依赖于 block.timestamp 的参数
    }


    /// @dev 状态指纹获取器。
    /// @param tokenId 所查询的令牌状态的ID。
    /// @return 当前令牌状态指纹。
    function getStateFingerprint(uint256 tokenId) override public view returns (bytes32) {
        State storage state = states[tokenId];

        return keccak256(
            abi.encode(
                state.asset1,
                state.asset2,
                state.amount1,
                state.amount2,
                // state.fee 不需要成为指纹计算的一部分，因为它是不可变的
                // state.operator 不需要成为指纹计算的一部分，因为它是不可变的
                block.timestamp >= state.expiration
            )
        );
    }

    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return super.supportsInterface(interfaceId) ||
            interfaceId == type(ERC5646).interfaceId;
    }

}