ERC-5827: 自动续订额度扩展

pragma solidity ^0.8.0;

interface IERC5827 /* is ERC20, ERC165 */ {
    /*
     * Note: the ERC-165 identifier for this interface is 0x93cd7af6.
     * 0x93cd7af6 ===
     *   bytes4(keccak256('approveRenewable(address,uint256,uint256)')) ^
     *   bytes4(keccak256('renewableAllowance(address,address)')) ^
     *   bytes4(keccak256('approve(address,uint256)') ^
     *   bytes4(keccak256('transferFrom(address,address,uint256)') ^
     *   bytes4(keccak256('allowance(address,address)') ^
     */

    /**
     * @notice  当可用额度小于转账金额时抛出。
     * @param   available       可用额度; 如果未设置则为 0
     */
    error InsufficientRenewableAllowance(uint256 available);

    /**
     * @notice  当设置任何额度时发出。
     * @dev     即使设置了不可续订的额度，也 MUST 发出；如果是这样，则
     * @dev     `_recoveryRate` 必须为 0。
     * @param   _owner          token 的所有者
     * @param   _spender        token 允许的消费方
     * @param   _value          授予消费方的初始和最大额度
     * @param   _recoveryRate   每秒恢复的金额
     */
    event RenewableApproval(
        address indexed _owner,
        address indexed _spender,
        uint256 _value,
        uint256 _recoveryRate
    );

    /**
     * @notice  最初授予 `_spender` `_value` 的额度，该额度随时间恢复
     * @notice  以 `_recoveryRate` 的速率恢复，最高可达 `_value` 的限制。
     * @dev     SHOULD 导致 `allowance(address _owner, address _spender)` 返回 `_value`，
     * @dev     当 `_recoveryRate` 大于 `_value` 时，SHOULD 抛出，并且必须发出
     * @dev     `RenewableApproval` 事件。
     * @param   _spender        token 允许的消费方
     * @param   _value          授予消费方的初始和最大额度
     * @param   _recoveryRate   每秒恢复的金额
     */
    function approveRenewable(
        address _spender,
        uint256 _value,
        uint256 _recoveryRate
    ) external returns (bool success);

    /**
     * @notice  返回授予 `_spender` 的额度批准的最大金额和恢复率
     * @notice  由 `_owner`。
     * @dev     当已授予不可续订的额度时，例如使用 `approve(address _spender, uint256 _value)`，
     * @dev     `amount` 也必须是初始批准金额。
     * @param    _owner         token 的所有者
     * @param   _spender        token 允许的消费方
     * @return  amount 授予消费方的初始和最大额度
     * @return  recoveryRate 每秒恢复的金额
     */
    function renewableAllowance(address _owner, address _spender)
        external
        view
        returns (uint256 amount, uint256 recoveryRate);

    /// Overridden ERC-20 functions

    /**
     * @notice  授予 `_spender` `_value` 的（非递增）额度，并清除任何现有的
     * @notice  可续订的额度。
     * @dev     如果
     * @dev     有任何可续订的额度，则必须清除集合 `_recoveryRate` 为 0。
     * @param   _spender        token 允许的消费方
     * @param   _value          授予消费方的额度
     */
    function approve(address _spender, uint256 _value)
        external
        returns (bool success);

    /**
    * @notice   使用调用者的额度将 `amount` 个 token 从 `from` 移动到 `to`。
    * @dev      当从调用者的额度中扣除 `amount` 时，使用的额度数量
    * @dev      SHOULD 包括自上次转账以来恢复的金额，但 MUST NOT 超过 `renewableAllowance(address _owner, address
    * @dev      _spender)` 返回的最大允许金额。
    * @dev      当额度不足时，还 SHOULD 抛出 `InsufficientRenewableAllowance`。
    * @param    from            token 所有者地址
    * @param    to              token 接收者
    * @param    amount          要转移的 token 数量
    */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);

    /**
     * @notice  返回 `_spender` 当前可消费的金额。
     * @dev     如果存在 `_owner` 和 `_spender` 的可续订额度，则返回的金额必须是 `block.timestamp` 的金额。
     * @param   _owner         token 的所有者
     * @param   _spender       token 允许的消费方
     * @return  remaining 当前时间点的剩余额度
     */
    function allowance(address _owner, address _spender)
        external
        view
        returns (uint256 remaining);
}

interface IERC5827Proxy /* is IERC5827 */ {

    /*
     * Note: the ERC-165 identifier for this interface is 0xc55dae63.
     * 0xc55dae63 ===
     *   bytes4(keccak256('baseToken()')
     */

    /**
     * @notice   获取正在代理的底层基本 token。
     * @return   baseToken 基本 token 的地址
     */
    function baseToken() external view returns (address);
}

interface IERC5827Expirable /* is IERC5827 */ {
    /*
     * Note: the ERC-165 identifier for this interface is 0x46c5b619.
     * 0x46c5b619 ===
     *   bytes4(keccak256('approveRenewable(address,uint256,uint256,uint64)')) ^
     *   bytes4(keccak256('renewableAllowance(address,address)')) ^
     */

    /**
     * @notice  最初授予 `_spender` `_value` 的额度，该额度随时间恢复
     * @notice  以 `_recoveryRate` 的速率恢复，最高可达 `_value` 的限制，并在
     * @notice  `_expiration` 到期。
     * @dev     当 `_recoveryRate` 大于 `_value` 时，SHOULD 抛出，并且必须发出
     * @dev     `RenewableApproval` 事件。
     * @param   _spender        token 允许的消费方
     * @param   _value          最初授予消费方的额度
     * @param   _recoveryRate   每秒恢复的金额
     * @param   _expiration     额度到期的 Unix 时间（以秒为单位）
     */
    function approveRenewable(
        address _spender,
        uint256 _value,
        uint256 _recoveryRate,
        uint64 _expiration
    ) external returns (bool success);

    /**
     * @notice  返回批准的最大金额、恢复率和到期时间戳。
     * @return  amount 授予消费方的初始和最大额度
     * @return  recoveryRate 每秒恢复的金额
     * @return  expiration 额度到期的 Unix 时间（以秒为单位）
     */
    function renewableAllowance(address _owner, address _spender)
        external
        view
        returns (uint256 amount, uint256 recoveryRate, uint64 expiration);
}