ERC-6066: NFT 的签名验证方法

pragma solidity ^0.8.0;

interface IERC6066 {
    /**
     * @dev 如果提供的签名对于提供的 tokenId 和哈希有效，则必须返回
     * @param tokenId   签名 NFT 的 Token ID
     * @param hash      要签名的数据的哈希
     * @param data      可能有助于验证的可选任意数据
     *
     * 当函数通过时，必须返回 bytes4 魔术值 0x12edb34f。
     * 必须不修改状态（对于 solc < 0.5 使用 STATICCALL，对于 solc > 0.5 使用 view 修饰符）
     * 必须允许外部调用
     *
     */
    function isValidSignature(
        uint256 tokenId,
        bytes32 hash,
        bytes calldata data
    ) external view returns (bytes4 magicValue);
}

pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import "./interfaces/IERC6066.sol";

contract ERC6066Reference is ERC721, IERC6066 {
    // type(IERC6066).interfaceId
    bytes4 public constant MAGICVALUE = 0x12edb34f;
    bytes4 public constant BADVALUE = 0xffffffff;

    mapping(uint256 => mapping(bytes32 => bool)) internal _signatures;

    error ENotTokenOwner();

    /**
     * @dev 检查发送者是否拥有 ID 为 tokenId 的 NFT
     * @param tokenId   签名 NFT 的 Token ID
     */
    modifier onlyTokenOwner(uint256 tokenId) {
        if (ownerOf(tokenId) != _msgSender()) revert ENotTokenOwner();
        _;
    }

    constructor(string memory name_, string memory symbol_)
        ERC721(name_, symbol_)
    {}

    /**
     * @dev 如果给定发送者拥有所述 NFT，则应该使用 tokenId 的 NFT 签署提供的哈希
     * @param tokenId   签名 NFT 的 Token ID
     * @param hash      要签名的数据的哈希
     */
    function sign(uint256 tokenId, bytes32 hash)
        external
        onlyTokenOwner(tokenId)
    {
        _signatures[tokenId][hash] = true;
    }

    /**
     * @dev 如果提供的签名对于提供的 tokenId、哈希以及可选的数据有效，则必须返回
     */
    function isValidSignature(uint256 tokenId, bytes32 hash, bytes calldata data)
        external
        view
        override
        returns (bytes4 magicValue)
    {
        // 在此示例中未使用 data 参数
        return _signatures[tokenId][hash] ? MAGICVALUE : BADVALUE;
    }

    /**
     * @dev ERC-165 支持
     */
    function supportsInterface(
        bytes4 interfaceId
    ) public view virtual override returns (bool) {
        return
            interfaceId == type(IERC6066).interfaceId ||
            super.supportsInterface(interfaceId);
    }
}