ERC-6381: 公共非同质化代币表情符号仓库

/// @title ERC-6381 非同质化代币的表情符号扩展
/// @dev 参见 https://eips.ethereum.org/EIPS/eip-6381
/// @dev 注意：此接口的 ERC-165 标识符为 0xd9fac55a。

pragma solidity ^0.8.16;

interface IERC6381 /*is IERC165*/ {
    /**
     * @notice 用于通知监听器具有指定 ID 的代币已被表情反应或反应已被撤销。
     * @dev 仅当表情符号的状态发生更改时，才必须发出该事件。
     * @param emoter 对代币做出表情反应或撤销反应的帐户地址
     * @param collection 包含被表情反应或撤销反应的代币的集合智能合约地址
     * @param tokenId 代币的 ID
     * @param emoji 表情符号的 Unicode 标识符
     * @param on 布尔值，表示是否对代币进行了表情反应 (`true`)，或者反应是否已被撤销 (`false`)
     */
    event Emoted(
        address indexed emoter,
        address indexed collection,
        uint256 indexed tokenId,
        bytes4 emoji,
        bool on
    );

    /**
     * @notice 用于获取代币上特定表情符号的表情符号数量。
     * @param collection 包含正在检查表情符号数量的代币的集合地址
     * @param tokenId 要检查表情符号数量的代币的 ID
     * @param emoji 表情符号的 Unicode 标识符
     * @return 代币上带有表情符号的表情数量
     */
    function emoteCountOf(
        address collection,
        uint256 tokenId,
        bytes4 emoji
    ) external view returns (uint256);

    /**
     * @notice 用于获取一组代币上特定表情符号的表情符号数量。
     * @param collections 包含正在检查表情符号数量的代币的集合地址数组
     * @param tokenIds 要检查表情符号数量的代币的 ID 数组
     * @param emojis 表情符号的 Unicode 标识符数组
     * @return 代币上带有表情符号的表情数量数组
     */
    function bulkEmoteCountOf(
        address[] memory collections,
        uint256[] memory tokenIds,
        bytes4[] memory emojis
    ) external view returns (uint256[] memory);

    /**
     * @notice 用于获取有关指定地址是否在特定代币上使用了特定表情符号的信息。
     * @param emoter 我们要检查其对代币的反应的帐户地址
     * @param collection 包含要检查表情符号反应的代币的集合智能合约地址
     * @param tokenId 要检查表情符号反应的代币的 ID
     * @param emoji 要检查反应的 ASCII 表情符号代码
     * @return 一个布尔值，指示 `emoter` 是否在代币上使用了 `emoji` (`true`) 或未 (`false`)
     */
    function hasEmoterUsedEmote(
        address emoter,
        address collection,
        uint256 tokenId,
        bytes4 emoji
    ) external view returns (bool);

    /**
     * @notice 用于获取有关指定地址是否在特定代币上使用了特定表情符号的信息。
     * @param emoters 我们要检查其对代币的反应的帐户地址数组
     * @param collections 包含要检查表情符号反应的代币的集合智能合约地址数组
     * @param tokenIds 要检查表情符号反应的代币的 ID 数组
     * @param emojis 要检查反应的 ASCII 表情符号代码数组
     * @return 一个布尔值数组，指示 `emoter`s 是否在代币上使用了 `emoji`s (`true`) 或未 (`false`)
     */
    function haveEmotersUsedEmotes(
        address[] memory emoters,
        address[] memory collections,
        uint256[] memory tokenIds,
        bytes4[] memory emojis
    ) external view returns (bool[] memory);

    /**
     * @notice 用于获取要由 `emoter` 签名的消息，以便他人可以提交反应。
     * @param collection 包含要进行表情反应的代币的集合智能合约地址
     * @param tokenId 要进行表情反应的代币的 ID
     * @param emoji 表情符号的 Unicode 标识符
     * @param state 布尔值，表示是否进行表情 (`true`) 或撤消 (`false`) 表情
     * @param deadline 提交签名的截止时间的 UNIX 时间戳
     * @return 要由 `emoter` 签名的消息，以便他人可以提交反应
     */
    function prepareMessageToPresignEmote(
        address collection,
        uint256 tokenId,
        bytes4 emoji,
        bool state,
        uint256 deadline
    ) external view returns (bytes32);

    /**
     * @notice 用于获取多个要由 `emoter` 签名的消息，以便他人可以提交反应。
     * @param collections 包含要进行表情反应的代币的集合智能合约地址数组
     * @param tokenIds 要进行表情反应的代币的 ID 数组
     * @param emojis 表情符号的 Unicode 标识符数组
     * @param states 布尔值数组，表示是否进行表情 (`true`) 或撤消 (`false`) 表情
     * @param deadlines 提交签名的截止时间的 UNIX 时间戳数组
     * @return 要由 `emoter` 签名的消息数组，以便他人可以提交反应
     */
    function bulkPrepareMessagesToPresignEmote(
        address[] memory collections,
        uint256[] memory tokenIds,
        bytes4[] memory emojis,
        bool[] memory states,
        uint256[] memory deadlines
    ) external view returns (bytes32[] memory);

    /**
     * @notice 用于对代币进行表情反应或撤消表情反应。
     * @dev 如果尝试设置预先存在的状态，则不执行任何操作。
     * @dev 如果表情符号的状态发生更改，则必须发出 `Emoted` 事件。
     * @param collection 包含要进行表情反应的代币的集合地址
     * @param tokenId 要进行表情反应的代币的 ID
     * @param emoji 表情符号的 Unicode 标识符
     * @param state 布尔值，表示是否进行表情 (`true`) 或撤消 (`false`) 表情
     */
    function emote(
        address collection,
        uint256 tokenId,
        bytes4 emoji,
        bool state
    ) external;

    /**
     * @notice 用于对多个代币进行表情反应或撤消表情反应。
     * @dev 如果尝试设置预先存在的状态，则不执行任何操作。
     * @dev 如果表情符号的状态发生更改，则必须发出 `Emoted` 事件。
     * @dev 如果 `collections`、`tokenIds`、`emojis` 和 `states` 数组的长度不相等，则必须恢复。
     * @param collections 包含要进行表情反应的代币的集合地址数组
     * @param tokenIds 要进行表情反应的代币的 ID 数组
     * @param emojis 表情符号的 Unicode 标识符数组
     * @param states 布尔值数组，表示是否进行表情 (`true`) 或撤消 (`false`) 表情
     */
    function bulkEmote(
        address[] memory collections,
        uint256[] memory tokenIds,
        bytes4[] memory emojis,
        bool[] memory states
    ) external;

    /**
     * @notice 用于代表他人对代币进行表情反应或撤消表情反应。
     * @dev 如果尝试设置预先存在的状态，则不执行任何操作。
     * @dev 如果表情符号的状态发生更改，则必须发出 `Emoted` 事件。
     * @dev 如果 `collections`、`tokenIds`、`emojis` 和 `states` 数组的长度不相等，则必须恢复。
     * @dev 如果 `deadline` 已过，则必须恢复。
     * @dev 如果恢复的地址为零地址，则必须恢复。
     * @param emoter 预先签署表情符号的地址
     * @param collection 包含要进行表情反应的代币的集合智能合约地址
     * @param tokenId 要进行表情反应的代币的 ID
     * @param emoji 表情符号的 Unicode 标识符
     * @param state 布尔值，表示是否进行表情 (`true`) 或撤消 (`false`) 表情
     * @param deadline 提交签名的截止时间的 UNIX 时间戳
     * @param v 通过 `prepareMessageToPresignEmote` 获取的消息的 ECDSA 签名的 `v` 值
     * @param r 通过 `prepareMessageToPresignEmote` 获取的消息的 ECDSA 签名的 `r` 值
     * @param s 通过 `prepareMessageToPresignEmote` 获取的消息的 ECDSA 签名的 `s` 值
     */
    function presignedEmote(
        address emoter,
        address collection,
        uint256 tokenId,
        bytes4 emoji,
        bool state,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @notice 用于批量代表他人对代币进行表情反应或撤消表情反应。
     * @dev 如果尝试设置预先存在的状态，则不执行任何操作。
     * @dev 如果表情符号的状态发生更改，则必须发出 `Emoted` 事件。
     * @dev 如果 `collections`、`tokenIds`、`emojis` 和 `states` 数组的长度不相等，则必须恢复。
     * @dev 如果 `deadline` 已过，则必须恢复。
     * @dev 如果恢复的地址为零地址，则必须恢复。
     * @param emoters 预先签署表情符号的帐户地址数组
     * @param collections 包含要进行表情反应的代币的集合地址数组
     * @param tokenIds 要进行表情反应的代币的 ID 数组
     * @param emojis 表情符号的 Unicode 标识符数组
     * @param states 布尔值数组，表示是否进行表情 (`true`) 或撤消 (`false`) 表情
     * @param deadlines 提交签名的截止时间的 UNIX 时间戳
     * @param v 通过 `prepareMessageToPresignEmote` 获取的消息的 ECDSA 签名的 `v` 值数组
     * @param r 通过 `prepareMessageToPresignEmote` 获取的消息的 ECDSA 签名的 `r` 值数组
     * @param s 通过 `prepareMessageToPresignEmote` 获取的消息的 ECDSA 签名的 `s` 值数组
     */
    function bulkPresignedEmote(
        address[] memory emoters,
        address[] memory collections,
        uint256[] memory tokenIds,
        bytes4[] memory emojis,
        bool[] memory states,
        uint256[] memory deadlines,
        uint8[] memory v,
        bytes32[] memory r,
        bytes32[] memory s
    ) external;
}

keccak256(
        abi.encode(
            DOMAIN_SEPARATOR,
            collection,
            tokenId,
            emoji,
            state,
            deadline
        )
    );

keccak256(
        abi.encode(
            "ERC-6381: Public Non-Fungible Token Emote Repository",
            "1",
            block.chainid,
            address(this)
        )
    );