ERC-6682: NFT 闪电贷

pragma solidity ^0.8.19;

interface IERC6682 {
    /// @dev 用于支付闪电贷费用的代币地址。
    function flashFeeToken() external view returns (address);

    /// @dev NFT 是否可用于闪电贷。
    /// @param token NFT 合约的地址。
    /// @param tokenId NFT 的 ID。
    function availableForFlashLoan(address token, uint256 tokenId) external view returns (bool);
}

function maxFlashLoan(address token) public pure override returns (uint256) {
    // if a contract also supports flash loans for ERC20 tokens then it can
    // 如果合约还支持 ERC20 代币的闪电贷，则它可以
    // return some value here instead of 1
    // 在这里返回一些值而不是 1
    return 1;
}

// SPDX-License-Identifier: CC0-1.0
pragma solidity ^0.8.19;

import "../interfaces/IERC20.sol";
import "../interfaces/IERC721.sol";
import "../interfaces/IERC3156FlashBorrower.sol";
import "../interfaces/IERC3156FlashLender.sol";
import "../interfaces/IERC6682.sol";

contract ExampleFlashLender is IERC6682, IERC3156FlashLender {
    uint256 internal _feePerNFT;
    address internal _flashFeeToken;

    constructor(uint256 feePerNFT_, address flashFeeToken_) {
        _feePerNFT = feePerNFT_;
        _flashFeeToken = flashFeeToken_;
    }

    function flashFeeToken() public view returns (address) {
        return _flashFeeToken;
    }

    function availableForFlashLoan(address token, uint256 tokenId) public view returns (bool) {
        // return if the NFT is owned by this contract
        // 如果 NFT 由此合约拥有，则返回
        try IERC721(token).ownerOf(tokenId) returns (address result) {
            return result == address(this);
        } catch {
            return false;
        }
    }

    function flashFee(address token, uint256 tokenId) public view returns (uint256) {
        return _feePerNFT;
    }

    function flashLoan(IERC3156FlashBorrower receiver, address token, uint256 tokenId, bytes calldata data)
        public
        returns (bool)
    {
        // check that the NFT is available for a flash loan
        // 检查 NFT 是否可用于闪电贷
        require(availableForFlashLoan(token, tokenId), "IERC6682: NFT not available for flash loan");

        // transfer the NFT to the borrower
        // 将 NFT 转移给借款人
        IERC721(token).safeTransferFrom(address(this), address(receiver), tokenId);

        // calculate the fee
        // 计算费用
        uint256 fee = flashFee(token, tokenId);

        // call the borrower
        // 调用借款人
        bool success =
            receiver.onFlashLoan(msg.sender, token, tokenId, fee, data) == keccak256("ERC3156FlashBorrower.onFlashLoan");

        // check that flashloan was successful
        // 检查闪电贷是否成功
        require(success, "IERC6682: Flash loan failed");
        
        // check that the NFT was returned by the borrower
        // 检查 NFT 是否已由借款人退回
        require(IERC721(token).ownerOf(tokenId) == address(this), "IERC6682: NFT not returned by borrower");

        // transfer the fee from the borrower
        // 从借款人处转移费用
        IERC20(flashFeeToken()).transferFrom(msg.sender, address(this), fee);

        return success;
    }

    function maxFlashLoan(address token) public pure override returns (uint256) {
        // if a contract also supports flash loans for ERC20 tokens then it can
        // 如果合约还支持 ERC20 代币的闪电贷，则它可以
        // return some value here instead of 1
        // 在这里返回一些值而不是 1
        return 1;
    }

    function onERC721Received(address, address, uint256, bytes memory) public returns (bytes4) {
        return this.onERC721Received.selector;
    }
}