ERC-6864: 可升级的同质化代币

pragma solidity ^0.8.0;

/**
    @title 可升级的同质化代币
    @dev 参见 https://eips.ethereum.org/EIPS/eip-6864
 */
interface IERC6864 is IERC20 {
    /**
      @dev 当代币被升级时，必须发出
      @param from 基础 ERC-20 代币的先前所有者
      @param to ERC-6864 代币的新所有者
      @param amount 被升级的数量
    */
    event Upgrade(address indexed from, address indexed to, uint256 amount);

    /**
      @dev 当代币被降级时，必须发出
      @param from ERC-6864 代币的先前所有者
      @param to 基础 ERC-20 代币的新所有者
      @param amount 被降级的数量
    */
    event Downgrade(address indexed from, address indexed to, uint256 amount);

    /**
      @notice 将 `msg.sender` 拥有的 `amount` 个基础 ERC-20 代币升级为 `to` 名下的 ERC-6864 代币
      @dev `msg.sender` 必须直接拥有足够的基础 ERC-20 代币
      如果 `to` 是零地址，则必须回退
      如果 `msg.sender` 没有直接拥有 `amount` 个或更多的基础 ERC-20 代币，则必须回退
      @param to 接收 ERC-6864 代币的地址
      @param amount 要升级的基础 ERC-20 代币的数量
    */
    function upgrade(address to, uint256 amount) external;

    /**
      @notice 将 `from` 拥有的 `amount` 个 ERC-6864 代币降级为 `to` 名下的基础 ERC-20 代币
      @dev `msg.sender` 必须直接拥有或被批准花费 `from` 的足够 ERC-6864 代币
      如果 `to` 是零地址，则必须回退
      如果 `from` 没有直接拥有 `amount` 个或更多的 ERC-6864 代币，则必须回退
      如果 `msg.sender` 不是 `from` 且未被批准为 `from` 花费 `amount` 或更多的 ERC-6864 代币，则必须回退
      @param from 释放 ERC-6864 代币的地址
      @param to 接收基础 ERC-20 代币的地址
      @param amount 要降级的 ERC-6864 代币的数量
    */
    function downgrade(address from, address to, uint256 amount) external;

    /**
      @notice 获取基础 ERC-20 智能合约地址
      @return 基础 ERC-20 智能合约的地址
    */
    function baseToken() external view returns (address);
}

pragma solidity ^0.8.0;

interface IERC6864SeeThrough is IERC6864 {
  /**
    @notice 获取此 ERC-6864 和基础 ERC-20 智能合约之间的组合代币总供应量
    @return 组合代币总供应量
  */
  function combinedTotalSupply() external view returns (uint256);

  /**
    @notice 获取 `account` 在此 ERC-6864 和基础 ERC-20 智能合约之间的组合代币余额
    @param account 拥有代币的地址
    @return 组合代币余额
  */
  function combinedBalanceOf(address account) external view returns (uint256);

  /**
    @notice 获取 `spender` 可以为 `owner` 花费的、在此 ERC-6864 和基础 ERC-20 智能合约之间的组合授权额度
    @param owner 拥有代币的地址
    @param spender 被批准花费代币的地址
    @return 组合花费授权额度
  */
  function combinedAllowance(address owner, address spender) external view returns (uint256);
}

import {IERC20, ERC20} from "@openzeppelin-contracts/token/ERC20/ERC20.sol";

contract ERC6864 is IERC6864, ERC20 {
  IERC20 private immutable s_baseToken;

    constructor(string memory name, string memory symbol, address baseToken_) ERC20(name, symbol) {
        s_baseToken = IERC20(baseToken_);
    }

    function baseToken() public view virtual override returns (address) {
        return address(s_baseToken);
    }

    function upgrade(address to, uint256 amount) public virtual override {
        address from = _msgSender();

        s_baseToken.transferFrom(from, address(this), amount);
        _mint(to, amount);

        emit Upgrade(from, to, amount);
    }

    function downgrade(address from, address to, uint256 amount) public virtual override {
        address spender = _msgSender();

        if (from != spender) {
            _spendAllowance(from, spender, amount);
        }
        _burn(from, amount);
        s_baseToken.transfer(to, amount);

        emit Downgrade(from, to, amount);
    }

    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address from = _msgSender();
        uint256 balance = balanceOf(from);

        if (balance < amount) {
            upgrade(from, amount - balance);
        }

        _transfer(from, to, amount);
        return true;
    }

    function totalSupply() public view virtual override returns (uint256) {
        return super.totalSupply() + s_baseToken.totalSupply() - s_baseToken.balanceOf(address(this));
    }

    function balanceOf(address account) public view virtual override returns (uint256) {
        return super.balanceOf(account) + s_baseToken.balanceOf(account);
    }
}