ERC-7160: ERC-721 多元数据扩展

/// @title EIP-721 多元数据扩展
/// @dev 此接口的 ERC-165 标识符为 0x06e1bc5b。
interface IERC7160 {

  /// @dev 当 token uri 被固定时，会发出此事件
  ///  对索引编制很有用。
  event TokenUriPinned(uint256 indexed tokenId, uint256 indexed index);

  /// @dev 当 token uri 被取消固定时，会发出此事件
  ///  对索引编制很有用。
  event TokenUriUnpinned(uint256 indexed tokenId);

  /// @notice 获取与特定 token 关联的所有 token uri
  /// @dev 如果 token uri 被固定，则返回的索引应该是字符串数组中的索引
  /// @dev 如果 token 不存在，则此调用必须恢复
  /// @param tokenId nft 的标识符
  /// @return index 一个 unisgned 整数，用于指定为 token 固定哪个 uri（如果未固定，则为默认 uri）
  /// @return uris 与 token 关联的所有 uri 的字符串数组
  /// @return pinned 一个布尔值，显示该 token 是否具有固定的元数据
  function tokenURIs(uint256 tokenId) external view returns (uint256 index, string[] memory uris, bool pinned);

  /// @notice 为特定 token 固定一个特定的 token uri
  /// @dev 如果 token 不存在，则此调用必须恢复
  /// @dev 此调用必须发出一个 `TokenUriPinned` 事件
  /// @dev 此调用可以发出 ERC-4096 中的 `MetadataUpdate` 事件
  /// @param tokenId nft 的标识符
  /// @param index 从 `tokenURIs` 函数返回的字符串数组中的索引，该索引应为 token 固定
  function pinTokenURI(uint256 tokenId, uint256 index) external;

  /// @notice 取消固定特定 token 的元数据
  /// @dev 如果 token 不存在，则此调用必须恢复
  /// @dev 此调用必须发出一个 `TokenUriUnpinned` 事件
  /// @dev 此调用可以发出 ERC-4096 中的 `MetadataUpdate` 事件
  /// @dev 由开发人员定义此函数的功能，并故意保持开放性
  /// @param tokenId nft 的标识符
  function unpinTokenURI(uint256 tokenId) external;

  /// @notice 在链上检查 token id 是否具有固定的 uri
  /// @dev 如果 token 不存在，则此调用必须恢复
  /// @dev 适用于不需要 tokenURIs 本身的链上机制
  /// @param tokenId nft 的标识符
  /// @return pinned 一个布尔值，用于指定 token 是否具有固定的元数据
  function hasPinnedTokenURI(uint256 tokenId) external view returns (bool pinned);
}

// SPDX-License-Identifier: CC0-1.0

pragma solidity ^0.8.19;

import {ERC721} from "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {IERC4906} from "@openzeppelin/contracts/interfaces/IERC4906.sol";
import {IERC7160} from "./IERC7160.sol";

contract MultiMetadata is ERC721, Ownable, IERC7160, IERC4906 {
  mapping(uint256 => string[]) private _tokenURIs;
  mapping(uint256 => uint256) private _pinnedURIIndices;
  mapping(uint256 => bool) private _hasPinnedTokenURI;

  constructor(string memory _name, string memory _symbol) ERC721(_name, _symbol) Ownable() {
    _mint(msg.sender, 1);
  }

  // @notice 返回固定的 URI 索引或最后一个 token URI 索引（长度 - 1）。
  function _getTokenURIIndex(uint256 tokenId) internal view returns (uint256) {
    return _hasPinnedTokenURI[tokenId] ? _pinnedURIIndices[tokenId] : _tokenURIs[tokenId].length - 1;
  }

  // @notice 为向后兼容性实现 ERC721.tokenURI。
  // @inheritdoc ERC721.tokenURI
  function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
    _requireMinted(tokenId);

    uint256 index = _getTokenURIIndex(tokenId);
    string[] memory uris = _tokenURIs[tokenId];
    string memory uri = uris[index];

    // 如果找不到 token 的 URI，则恢复。
    require(bytes(uri).length > 0, "ERC721: not URI found");
    return uri;
  }

  /// @inheritdoc IERC721MultiMetadata.tokenURIs
  function tokenURIs(uint256 tokenId) external view returns (uint256 index, string[] memory uris, bool pinned) {
    _requireMinted(tokenId);
    return (_getTokenURIIndex(tokenId), _tokenURIs[tokenId], _hasPinnedTokenURI[tokenId]);
  }

  /// @inheritdoc IERC721MultiMetadata.pinTokenURI
  function pinTokenURI(uint256 tokenId, uint256 index) external {
    require(msg.sender == ownerOf(tokenId), "Unauthorized");
    _pinnedURIIndices[tokenId] = index;
    _hasPinnedTokenURI[tokenId] = true;
    emit TokenUriPinned(tokenId, index);
  }

  /// @inheritdoc IERC721MultiMetadata.unpinTokenURI
  function unpinTokenURI(uint256 tokenId) external {
    require(msg.sender == ownerOf(tokenId), "Unauthorized");
    _pinnedURIIndices[tokenId] = 0;
    _hasPinnedTokenURI[tokenId] = false;
    emit TokenUriUnpinned(tokenId);
  }

  /// @inheritdoc IERC721MultiMetadata.hasPinnedTokenURI
  function hasPinnedTokenURI(uint256 tokenId) external view returns (bool pinned) {
    return _hasPinnedTokenURI[tokenId];
  }

  /// @notice 为给定索引处的 token 设置特定的元数据 URI。
  function setUri(uint256 tokenId, uint256 index, string calldata uri) external onlyOwner {
    if (_tokenURIs[tokenId].length > index) {
      _tokenURIs[tokenId][index] = uri;
    } else {
      _tokenURIs[tokenId].push(uri);
    }

    emit MetadataUpdate(tokenId);
  }

  // 覆盖 supportsInterface 以包含 IERC721MultiMetadata 接口支持。
  function supportsInterface(bytes4 interfaceId) public view virtual override(IERC165, ERC721) returns (bool) {
    return (
      interfaceId == type(IERC7160).interfaceId ||
      super.supportsInterface(interfaceId)
    );
  }
}