ERC-7409: 公共非同质化代币表情符号库

/// @title 用于非同质化代币的 ERC-7409 表情符号扩展
/// @dev 请参阅 https://eips.ethereum.org/EIPS/eip-7409
/// @dev 注意：此接口的 ERC-165 标识符是 0x1b3327ab。

pragma solidity ^0.8.16;

interface IERC7409 /*is IERC165*/ {
    /**
     * @notice 用于通知侦听器具有指定 ID 的代币已被使用表情符号或该反应已被撤销。
     * @dev 仅当表情符号的状态发生更改时才必须发出此事件。
     * @param emoter 使用表情符号或撤销对代币的反应的帐户地址
     * @param collection 包含正在使用表情符号或撤销反应的代币的集合智能合约地址
     * @param tokenId 代币的 ID
     * @param emoji 表情符号的 Unicode 标识符
     * @param on 布尔值，表示是否对代币使用了表情符号 (`true`) 或反应是否已撤销 (`false`)
     */
    event Emoted(
        address indexed emoter,
        address indexed collection,
        uint256 indexed tokenId,
        string emoji,
        bool on
    );

    /**
     * @notice 用于获取代币上特定表情符号的表情符号数量。
     * @param collection 包含要检查表情符号数量的代币的集合地址
     * @param tokenId 要检查表情符号数量的代币的 ID
     * @param emoji 表情符号的 Unicode 标识符
     * @return 代币上带有表情符号的表情符号数量
     */
    function emoteCountOf(
        address collection,
        uint256 tokenId,
        string memory emoji
    ) external view returns (uint256);

    /**
     * @notice 用于获取一组代币上特定表情符号的表情符号数量。
     * @param collections 包含要检查表情符号数量的代币的集合地址数组
     * @param tokenIds 要检查表情符号数量的代币 ID 数组
     * @param emojis 表情符号的 Unicode 标识符数组
     * @return 代币上带有表情符号的表情符号数量数组
     */
    function bulkEmoteCountOf(
        address[] memory collections,
        uint256[] memory tokenIds,
        string[] memory emojis
    ) external view returns (uint256[] memory);

    /**
     * @notice 用于获取有关指定地址是否在特定代币上使用了特定表情符号的信息。
     * @param emoter 我们要检查对代币的反应的帐户地址
     * @param collection 包含要检查表情符号反应的代币的集合智能合约地址
     * @param tokenId 要检查表情符号反应的代币的 ID
     * @param emoji 要检查反应的 ASCII 表情符号代码
     * @return 一个布尔值，指示 `emoter` 是否在代币上使用了 `emoji` (`true`) 或没有 (`false`)
     */
    function hasEmoterUsedEmote(
        address emoter,
        address collection,
        uint256 tokenId,
        string memory emoji
    ) external view returns (bool);

    /**
     * @notice 用于获取有关指定地址是否在特定代币上使用了特定表情符号的信息。
     * @param emoters 我们要检查对代币的反应的帐户地址数组
     * @param collections 包含要检查表情符号反应的代币的集合智能合约地址数组
     * @param tokenIds 要检查表情符号反应的代币 ID 数组
     * @param emojis 要检查反应的 ASCII 表情符号代码数组
     * @return 一个布尔值数组，指示 `emoter`s 是否在代币上使用了 `emoji`s (`true`) 或没有 (`false`)
     */
    function haveEmotersUsedEmotes(
        address[] memory emoters,
        address[] memory collections,
        uint256[] memory tokenIds,
        string[] memory emojis
    ) external view returns (bool[] memory);

    /**
     * @notice 用于获取要由 `emoter` 签名的消息，以便其他人可以提交反应。
     * @param collection 包含正在使用表情符号的代币的集合智能合约地址
     * @param tokenId 正在使用表情符号的代币的 ID
     * @param emoji 表情符号的 Unicode 标识符
     * @param state 布尔值，表示是否使用表情符号 (`true`) 或撤消 (`false`) 表情符号
     * @param deadline 用于提交签名的截止时间的 UNIX 时间戳
     * @return 要由 `emoter` 签名的消息，以便其他人可以提交反应
     */
    function prepareMessageToPresignEmote(
        address collection,
        uint256 tokenId,
        string memory emoji,
        bool state,
        uint256 deadline
    ) external view returns (bytes32);

    /**
     * @notice 用于获取要由 `emoter` 签名的多个消息，以便其他人可以提交反应。
     * @param collections 包含正在使用表情符号的代币的集合智能合约地址数组
     * @param tokenIds 正在使用表情符号的代币 ID 数组
     * @param emojis 表情符号的 Unicode 标识符数组
     * @param states 布尔值数组，表示是否使用表情符号 (`true`) 或撤消 (`false`) 表情符号
     * @param deadlines 用于提交签名的截止时间的 UNIX 时间戳数组
     * @return 要由 `emoter` 签名的消息数组，以便其他人可以提交反应
     */
    function bulkPrepareMessagesToPresignEmote(
        address[] memory collections,
        uint256[] memory tokenIds,
        string[] memory emojis,
        bool[] memory states,
        uint256[] memory deadlines
    ) external view returns (bytes32[] memory);

    /**
     * @notice 用于在代币上使用表情符号或撤消表情符号。
     * @dev 如果尝试设置预先存在的状态，则不执行任何操作。
     * @dev 如果表情符号的状态发生更改，则必须发出 `Emoted` 事件。
     * @param collection 包含正在使用表情符号的代币的集合地址
     * @param tokenId 正在使用表情符号的代币的 ID
     * @param emoji 表情符号的 Unicode 标识符
     * @param state 布尔值，表示是否使用表情符号 (`true`) 或撤消 (`false`) 表情符号
     */
    function emote(
        address collection,
        uint256 tokenId,
        string memory emoji,
        bool state
    ) external;

    /**
     * @notice 用于在多个代币上使用表情符号或撤消表情符号。
     * @dev 如果尝试设置预先存在的状态，则不执行任何操作。
     * @dev 如果表情符号的状态发生更改，则必须发出 `Emoted` 事件。
     * @dev 如果 `collections`、`tokenIds`、`emojis` 和 `states` 数组的长度不相等，则必须恢复。
     * @param collections 包含正在使用表情符号的代币的集合地址数组
     * @param tokenIds 正在使用表情符号的代币 ID 数组
     * @param emojis 表情符号的 Unicode 标识符数组
     * @param states 布尔值数组，表示是否使用表情符号 (`true`) 或撤消 (`false`) 表情符号
     */
    function bulkEmote(
        address[] memory collections,
        uint256[] memory tokenIds,
        string[] memory emojis,
        bool[] memory states
    ) external;

    /**
     * @notice 用于代表他人使用表情符号或撤消表情符号。
     * @dev 如果尝试设置预先存在的状态，则不执行任何操作。
     * @dev 如果表情符号的状态发生更改，则必须发出 `Emoted` 事件。
     * @dev 如果 `collections`、`tokenIds`、`emojis` 和 `states` 数组的长度不相等，则必须恢复。
     * @dev 如果 `deadline` 已过，则必须恢复。
     * @dev 如果恢复的地址是零地址，则必须恢复。
     * @param emoter 预先签署表情符号的地址
     * @param collection 包含正在使用表情符号的代币的集合智能合约地址
     * @param tokenId 正在使用表情符号的代币的 ID
     * @param emoji 表情符号的 Unicode 标识符
     * @param state 布尔值，表示是否使用表情符号 (`true`) 或撤消 (`false`) 表情符号
     * @param deadline 用于提交签名的截止时间的 UNIX 时间戳
     * @param v 通过 `prepareMessageToPresignEmote` 获得的 ECDSA 签名的 `v` 值
     * @param r 通过 `prepareMessageToPresignEmote` 获得的 ECDSA 签名的 `r` 值
     * @param s 通过 `prepareMessageToPresignEmote` 获得的 ECDSA 签名的 `s` 值
     */
    function presignedEmote(
        address emoter,
        address collection,
        uint256 tokenId,
        string memory emoji,
        bool state,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @notice 用于批量代表他人使用表情符号或撤消表情符号。
     * @dev 如果尝试设置预先存在的状态，则不执行任何操作。
     * @dev 如果表情符号的状态发生更改，则必须发出 `Emoted` 事件。
     * @dev 如果 `collections`、`tokenIds`、`emojis` 和 `states` 数组的长度不相等，则必须恢复。
     * @dev 如果 `deadline` 已过，则必须恢复。
     * @dev 如果恢复的地址是零地址，则必须恢复。
     * @param emoters 预先签署表情符号的帐户地址数组
     * @param collections 包含正在使用表情符号的代币的集合智能合约地址数组
     * @param tokenIds 正在使用表情符号的代币 ID 数组
     * @param emojis 表情符号的 Unicode 标识符数组
     * @param states 布尔值数组，表示是否使用表情符号 (`true`) 或撤消 (`false`) 表情符号
     * @param deadlines 用于提交签名的截止时间的 UNIX 时间戳
     * @param v 通过 `prepareMessageToPresignEmote` 获得的消息的 ECDSA 签名的 `v` 值数组
     * @param r 通过 `prepareMessageToPresignEmote` 获得的消息的 ECDSA 签名的 `r` 值数组
     * @param s 通过 `prepareMessageToPresignEmote` 获得的消息的 ECDSA 签名的 `s` 值数组
     */
    function bulkPresignedEmote(
        address[] memory emoters,
        address[] memory collections,
        uint256[] memory tokenIds,
        string[] memory emojis,
        bool[] memory states,
        uint256[] memory deadlines,
        uint8[] memory v,
        bytes32[] memory r,
        bytes32[] memory s
    ) external;
}

keccak256(
        abi.encode(
            DOMAIN_SEPARATOR,
            collection,
            tokenId,
            emoji,
            state,
            deadline
        )
    );

keccak256(
        abi.encode(
            "ERC-7409: Public Non-Fungible Token Emote Repository",
            "1",
            block.chainid,
            address(this)
        )
    );