ERC-7439: 防止倒卖门票

/// @title IERC7439 Prevent Ticket Touting Interface
// / @title IERC7439 防止倒卖门票接口
interface IERC7439 /* is ERC721 */ {
    /// @dev TokenStatus represent the token current status, only specific role can change status
    // / @dev TokenStatus 表示 token 当前状态，只有特定角色可以更改状态
    enum TokenStatus {
        Sold,    // 0
        Resell,  // 1
        Void,    // 2
        Redeemed // 3
    }

    /// @param signature Data signed by user's private key or agent's private key
    // / @param signature 由用户的私钥或代理的私钥签名的数据
    /// @param tokenStatus Token status changing to
    // / @param tokenStatus 要更改为的 token 状态
    /// @param expireTime Event due time
    // / @param expireTime 活动到期时间
    struct TokenInfo {
        bytes signature;
        TokenStatus tokenStatus;
        uint256 expireTime;
    }

    /// @notice Used to notify listeners that the token with the specified ID has been changed status
    // / @notice 用于通知监听器，具有指定 ID 的 token 状态已更改
    /// @param tokenId The token has been changed status
    // / @param tokenId 已更改状态的 token
    /// @param tokenStatus Token status has been changed to
    // / @param tokenStatus 已更改为的 token 状态
    /// @param signature Data signed by user's private key or agent's private key
    // / @param signature 由用户的私钥或代理的私钥签名的数据
    event TokenStatusChanged(
        uint256 indexed tokenId,
        TokenStatus indexed tokenStatus,
        bytes signature
    );

    /// @notice Used to mint token with token status
    // / @notice 用于使用 token 状态来铸造 token
    /// @dev MUST emit the `TokenStatusChanged` event if the token status is changed.
    // / @dev 如果 token 状态已更改，则必须发出 `TokenStatusChanged` 事件。
    /// @param to The receiptent of token
    // / @param to token 的接收者
    /// @param signature Data signed by user's private key or agent's private key
    // / @param signature 由用户的私钥或代理的私钥签名的数据
    function safeMint(address to, bytes memory signature) external;

    /// @notice Used to change token status and can only be invoked by a specific role
    // / @notice 用于更改 token 状态，并且只能由特定角色调用
    /// @dev MUST emit the `TokenStatusChanged` event if the token status is changed.
    // / @dev 如果 token 状态已更改，则必须发出 `TokenStatusChanged` 事件。
    /// @param tokenId The token need to change status
    // / @param tokenId 需要更改状态的 token
    /// @param signature Data signed by user's private key or agent's private key
    // / @param signature 由用户的私钥或代理的私钥签名的数据
    /// @param tokenStatus Token status changing to
    // / @param tokenStatus 要更改为的 token 状态
    /// @param newExpireTime New event due time
    // / @param newExpireTime 新的活动到期时间
    function changeState(
        uint256 tokenId,
        bytes memory signature,
        TokenStatus tokenStatus,
        uint256 newExpireTime
    ) external;
}

// SPDX-License-Identifier: CC0-1.0
pragma solidity 0.8.19;

import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
// If you need additional metadata, you can import ERC721URIStorage
// 如果你需要额外的元数据，你可以导入 ERC721URIStorage
// import "@openzeppelin/contracts/token/ERC721/extensions/ERC721URIStorage.sol";
import "@openzeppelin/contracts/access/AccessControl.sol";
import "@openzeppelin/contracts/utils/Counters.sol";
import "./IERC7439.sol";

contract ERC7439 is ERC721, AccessControl, IERC7439 {
    using Counters for Counters.Counter;

    bytes32 public constant PARTNER_ROLE = keccak256("PARTNER_ROLE");
    Counters.Counter private _tokenIdCounter;

    uint256 public expireTime;

    mapping(uint256 => TokenInfo) public tokenInfo;

    constructor(uint256 _expireTime) ERC721("MyToken", "MTK") {
        _grantRole(DEFAULT_ADMIN_ROLE, msg.sender);
        _grantRole(PARTNER_ROLE, msg.sender);
        expireTime = _expireTime;
    }

    function safeMint(address to, bytes memory signature) public {
        uint256 tokenId = _tokenIdCounter.current();
        _tokenIdCounter.increment();
        _safeMint(to, tokenId);
        tokenInfo[tokenId] = TokenInfo(signature, TokenStatus.Sold, expireTime);
        emit TokenStatusChanged(tokenId, TokenStatus.Sold, signature);
    }

    function changeState(
        uint256 tokenId,
        bytes memory signature,
        TokenStatus tokenStatus,
        uint256 newExpireTime
    ) public onlyRole(PARTNER_ROLE) {
        tokenInfo[tokenId] = TokenInfo(signature, tokenStatus, newExpireTime);
        emit TokenStatusChanged(tokenId, tokenStatus, signature);
    }
    
    function _burn(uint256 tokenId) internal virtual override(ERC721) {
        super._burn(tokenId);

        if (_exists(tokenId)) {
            delete tokenInfo[tokenId];
            // If you import ERC721URIStorage
            // 如果你导入 ERC721URIStorage
            // delete _tokenURIs[tokenId];
        }
    }

    function supportsInterface(
        bytes4 interfaceId
    ) public view virtual override(AccessControl, ERC721) returns (bool) {
        return
            interfaceId == type(IERC7439).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual override(ERC721) {
        if (!hasRole(PARTNER_ROLE, _msgSender())) {
            require(
                from == address(0) || to == address(0),
                "ERC7439: You cannot transfer this NFT!"
            );
        }

        super._beforeTokenTransfer(from, to, tokenId);
    }
}