ERC-7634: 有限转移次数 NFT

pragma solidity ^0.8.4;

/// @title IERC7634 有限可转移 NFT 接口
/// @dev ERC7634 有限可转移 NFT 扩展的接口，适用于 ERC721
/// @author Saber Yu

interface IERC7634 {

    /**
     * @dev 当转移计数被设置或更新时发出
     */
    event TransferCount(uint256 indexed tokenId, address owner, uint256 counts);

    /**
     * @dev 返回 tokenId 的当前转移计数
     */
    function transferCountOf(uint256 tokenId) external view returns (uint256);

    /**
     * @dev 设置 tokenId 的转移限制。只能由 token 所有者或批准的地址调用。
     * @param tokenId 要设置限制的 token 的 ID
     * @param limit 允许 token 转移的最大次数
     */
    function setTransferLimit(uint256 tokenId, uint256 limit) external;

    /**
     * @dev 返回 tokenId 的转移限制
     */
    function transferLimitOf(uint256 tokenId) external view returns (uint256);
}
    

pragma solidity ^0.8.4;

import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import "./IERC7634.sol";

/// @title ERC721 的有限可转移 NFT 扩展
/// @dev 有限可转移 NFT 扩展的实现，适用于 ERC721
/// @author Saber Yu

contract ERC7634 is ERC721, IERC7634 {

    // 从 tokenId 到转移计数的映射
    mapping(uint256 => uint256) private _transferCounts;

    // 从 tokenId 到其最大转移限制的映射
    mapping(uint256 => uint256) private _transferLimits;

    /**
     * @dev 参见 {IERC7634-transferCountOf}。
     */
    function transferCountOf(uint256 tokenId) public view override returns (uint256) {
        require(_exists(tokenId), "ERC7634: Nonexistent token");
        return _transferCounts[tokenId];
    }

    /**
     * @dev 参见 {IERC7634-setTransferLimit}。
     */
    function setTransferLimit(uint256 tokenId, uint256 limit) public override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC7634: caller is not owner nor approved");
        _transferLimits[tokenId] = limit;
    }

    /**
     * @dev 参见 {IERC7634-transferLimitOf}。
     */
    function transferLimitOf(uint256 tokenId) public view override returns (uint256) {
        require(_exists(tokenId), "ERC7634: Nonexistent token");
        return _transferLimits[tokenId];
    }

    /**
     * @dev 用于增加转移计数的内部函数。
     */
    function _incrementTransferCount(uint256 tokenId) internal {
        _transferCounts[tokenId] += 1;
        emit TransferCount(tokenId, ownerOf(tokenId), _transferCounts[tokenId]);
    }

    /**
     * @dev 重写 {_beforeTokenTransfer} 以强制执行转移限制。
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal override {
        require(_transferCounts[tokenId] < _transferLimits[tokenId], "ERC7634: Transfer limit reached");
        super._beforeTokenTransfer(from, to, tokenId);
    }

    /**
     * @dev 重写 {_afterTokenTransfer} 以处理转移后逻辑。
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 tokenId,
        uint256 quantity
    ) internal virtual override {
        _incrementTransferCount(tokenId);

        if (_transferCounts[tokenId] == _transferLimits[tokenId]) {
            // 达到限制后可选的转移后操作
            // 根据所需的行为取消注释以下内容，例如 `burn` 操作
            // ---------------------------------------
            // _burn(tokenId); // 销毁 token
            // ---------------------------------------
        }

        super._afterTokenTransfer(from, to, tokenId, quantity);
    }


    /**
     * @dev 重写 {supportsInterface} 以声明对 IERC7634 的支持。
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(IERC165, ERC721) returns (bool) {
        return interfaceId == type(IERC7634).interfaceId || super.supportsInterface(interfaceId);
    }
}