ERC-7683: 跨链意图

/// @title GaslessCrossChainOrder CrossChainOrder 类型
/// @notice 标准订单结构，供用户签名、分发给执行者，并由执行者提交给起始结算者合约
struct GaslessCrossChainOrder {
	/// @dev 订单要由其结算的合约地址。
	/// 执行者将此订单发送到起始链上的此合约地址
	address originSettler;
	/// @dev 发起交换的用户的地址，
	/// 其输入代币将被拿走并托管
	address user;
	/// @dev 用于订单重放保护的 Nonce
	uint256 nonce;
	/// @dev 起始链的 chainId
	uint256 originChainId;
	/// @dev 必须打开订单的时间戳
	uint32 openDeadline;
	/// @dev 必须在目标链上完成订单的时间戳
	uint32 fillDeadline;
	/// @dev 订单数据的类型标识符。这是一个 EIP-712 typehash。
	bytes32 orderDataType;
	/// @dev 任意的特定于实现的数据
	/// 可用于定义代币、金额、目标链、费用、结算参数，
	/// 或任何其他特定于订单类型的信息
	bytes orderData;
}

/// @title OnchainCrossChainOrder CrossChainOrder 类型
/// @notice 用于用户打开的订单的标准订单结构，其中用户是提交订单创建交易的人
struct OnchainCrossChainOrder {
	/// @dev 必须在目标链上完成订单的时间戳
	uint32 fillDeadline;
	/// @dev 订单数据的类型标识符。这是一个 EIP-712 typehash。
	bytes32 orderDataType;
	/// @dev 任意的特定于实现的数据
	/// 可用于定义代币、金额、目标链、费用、结算参数，
	/// 或任何其他特定于订单类型的信息
	bytes orderData;
}

/// @title ResolvedCrossChainOrder 类型
/// @notice 订单的实现通用表示，供执行者使用
/// @dev 通过解绑特定于实现的 orderData，定义了填写订单的所有要求。
/// @dev 旨在通过允许执行者计算任何订单的确切输入和输出信息来改进集成通用性
struct ResolvedCrossChainOrder {
	/// @dev 发起转移的用户的地址
	address user;
	/// @dev 起始链的 chainId
	uint256 originChainId;
	/// @dev 必须打开订单的时间戳
	uint32 openDeadline;
	/// @dev 必须在目标链上完成订单的时间戳
	uint32 fillDeadline;
	/// @dev 此结算系统中此订单的唯一标识符
	bytes32 orderId;

	/// @dev 执行者将发送的最大输出量。实际数量可能取决于目标的状态
	///      链（例如，目标荷兰式拍卖），因此这些输出应被视为对执行者责任的上限。
	Output[] maxSpent;
	/// @dev 必须作为订单结算的一部分提供给执行者的最小输出量。与 maxSpent 类似，
	///      特殊的订单类型可能无法保证打开时的确切数量，因此应将其视为
	///      执行者收据的下限。将`Output`的`recipient`设置为 address(0) 表示执行者不是
    ///      创建此订单时已知。
	Output[] minReceived;
	/// @dev 此数组中的每个指令都参数化了执行的单个腿。这为执行者提供了必要的信息
	///      在目标上执行填充。
	FillInstruction[] fillInstructions;
}

/// @notice 有效订单履行必须收到的代币
struct Output {
	/// @dev 目标链上 ERC20 代币的地址
	/// @dev address(0) 用作原生代币的哨兵
	bytes32 token;
	/// @dev 要发送的代币数量
	uint256 amount;
	/// @dev 接收输出代币的地址
	bytes32 recipient;
	/// @dev 此输出的目标链
	uint256 chainId;
}

/// @title FillInstruction 类型
/// @notice 参数化填充的每个腿的指令
/// @dev 提供了生成有效填充腿所需的所有起始生成的信息
struct FillInstruction {
	/// @dev 此指令旨在填充的链
	uint256 destinationChainId;
	/// @dev 此指令旨在填充的合约地址
	bytes32 destinationSettler;
	/// @dev 目标结算者处理填充所需的起始链上生成的数据
	bytes originData;
}

/// @notice 表示已打开订单
/// @param orderId 此结算系统中的唯一订单标识符
/// @param resolvedOrder 如果调用 resolve 而不是 Open 将返回的已解析订单
event Open(bytes32 indexed orderId, ResolvedCrossChainOrder resolvedOrder);

/// @title IOriginSettler
/// @notice 起始链上结算合约的标准接口
interface IOriginSettler {
	/// @notice 代表用户打开无 Gas 跨链订单。
	/// @dev 要由执行者调用。
	/// @dev 此方法必须发出 Open 事件
	/// @param order GaslessCrossChainOrder 定义
	/// @param signature 用户对订单的签名
	/// @param originFillerData 结算者需要的任何执行者定义的数据
	function openFor(GaslessCrossChainOrder calldata order, bytes calldata signature, bytes calldata originFillerData) external;

	/// @notice 打开跨链订单
	/// @dev 要由用户调用
	/// @dev 此方法必须发出 Open 事件
	/// @param order OnchainCrossChainOrder 定义
	function open(OnchainCrossChainOrder calldata order) external;

	/// @notice 将特定的 GaslessCrossChainOrder 解析为通用的 ResolvedCrossChainOrder
	/// @dev 旨在改善各种订单类型和结算合约的标准化集成
	/// @param order GaslessCrossChainOrder 定义
	/// @param originFillerData 结算者需要的任何执行者定义的数据
	/// @return ResolvedCrossChainOrder 包含订单输入和输出的 hydrated 订单数据
	function resolveFor(GaslessCrossChainOrder calldata order, bytes calldata originFillerData) external view returns (ResolvedCrossChainOrder memory);

	/// @notice 将特定的 OnchainCrossChainOrder 解析为通用的 ResolvedCrossChainOrder
	/// @dev 旨在改善各种订单类型和结算合约的标准化集成
	/// @param order OnchainCrossChainOrder 定义
	/// @return ResolvedCrossChainOrder 包含订单输入和输出的 hydrated 订单数据
	function resolve(OnchainCrossChainOrder calldata order) external view returns (ResolvedCrossChainOrder memory);
}

/// @title IDestinationSettler
/// @notice 目标链上结算合约的标准接口
interface IDestinationSettler {
	/// @notice 在目标链上填充特定订单的单个腿
	/// @param orderId 此订单的唯一订单标识符
	/// @param originData 起始链上发出的用于参数化填充的数据
	/// @param fillerData 执行者提供的数据，用于通知填充或表达其偏好
	function fill(bytes32 orderId, bytes calldata originData, bytes calldata fillerData) external;
}

// Message 子类型允许 ERC7683 意图携带在目标链上的目标合约上执行的 calldata。执行者在目标链上与之交互的结算合约会将 message 解码为智能合约调用，并在执行者的 `fill()` 交易中执行调用。

// Message 包含用户希望在目标链上执行的调用。
// target 是目标链上的一个合约，结算合约将尝试向其发送 callData 和 value。
struct Calls {
  address target;
  bytes callData;
  uint256 value;
}

struct Message {
  Calls[] calls;
}

function fill(bytes32 orderId, bytes calldata originData, bytes calldata fillerData) public {
	(
		address user,
		uint32 fillDeadline,
		Output memory fillerOutput,
		Message memory message
	) = abi.decode(originData);

	// ...在此处对参数进行一些预处理以验证订单...

	// ...执行 ResolvedCrossChainOrder 的填充逻辑...

	// 处理 Message 子类型：

        // 如果任何消息调用失败，则回滚。
        uint256 length = message.calls.length;
        for (uint256 i = 0; i < length; ++i) {
            Call memory call = message.calls[i];

            // 如果我们正在使用 calldata 调用 EOA，则假定 target 指示不正确并回滚。
            if (call.callData.length > 0 && call.target.code.length == 0) {
                revert InvalidCall(i, calls);
            }

            (bool success, ) = call.target.call{ value: call.value }(call.callData);
            if (!success) revert CallReverted(i, message.calls);
        }
    }