ERC-7699: ERC-20 转账引用扩展

// The EIP-165 identifier of this interface is 0x1522573a

interface IERC7699 {

function transfer(address to, uint256 amount, bytes calldata transferReference) external returns (bool);

function transferFrom(address from, address to, uint256 amount, bytes calldata transferReference) external returns (bool);

event TransferReference(bytes32 indexed loggedReference);

}

// SPDX-License-Identifier: CC0-1.0
pragma solidity >=0.8.4 <0.9.0;

import {ERC20} from "@openzeppelin/token/ERC20/ERC20.sol";

interface IERC7699 {
    /**
     * @notice 当非空的 `transferReference` 添加到 `transfer` 调用时发出。
     */
    event TransferReference(bytes32 indexed loggedReference);

    /**
     * @notice 使用 `transferReference` 将 `amount` 代币从调用者的帐户移动到 `to`。
     *
     * @dev 返回一个布尔值，指示操作是否成功。
     *
     * MUST 发出此 ERCS 的 {TransferReference} 事件，后跟相应的 {ERC20.Transfer} 事件
     * （为了符合 ERC-20）。
     */
    function transfer(address to, uint256 amount, bytes calldata transferReference) external returns (bool);

    /**
     * @notice 使用授权机制将 `amount` 代币从 `from` 移动到 `to`，并带有 `transferReference`。然后从调用者的授权中扣除 `amount`。
     *
     * @dev 返回一个布尔值，指示操作是否成功。
     *
     * MUST 发出此 ERCS 的 {TransferReference} 事件，后跟相应的 {ERC20.Transfer} 事件
     * （为了符合 ERC-20）。
     */
    function transferFrom(address from, address to, uint256 amount, bytes calldata transferReference)
        external
        returns (bool);
}

/**
 * @dev ERC20 转账引用扩展的实现。
 */
contract ERC20TransferReference is ERC20, IERC7699 {
    constructor() ERC20("ERC20 Transfer Reference Example", "TXRE") {
        _mint(msg.sender, 987654321 * 1e18);
    }

    /**
     * @dev 发出具有派生 `loggedReference` 数据的 `TransferReference` 事件
     */
    function _logReference(bytes calldata transferReference) internal virtual {
        // transferReference 为空时 MUST NOT 发出
        if (transferReference.length > 0) {
            // 有效地从 transferReference calldata 字节中提取前 32 个字节
            // 注意：这是一个示例。loggedReference 的推导完全取决于实现。
            // 例如，整个 transferReference 的 keccak 哈希等。
            bytes32 loggedReference;
            // solhint-disable-next-line no-inline-assembly
            assembly {
                loggedReference := calldataload(transferReference.offset)
            }

            emit TransferReference(loggedReference);
        }
    }

    /**
     * @notice 带有可选转账引用的标准 ERC20 代币转账
     * @dev 假定底层 `transfer` 函数处理实际的代币转账逻辑。
     * @param to 代币将发送到的接收者的地址。
     * @param amount 要转移的代币数量。
     * @param transferReference 用于包含转账引用、引用签名或其他相关
     * 参考数据的字节字段。
     * @return 一个布尔值，指示转账是否成功。
     */
    function transfer(address to, uint256 amount, bytes calldata transferReference) public virtual returns (bool) {
        _logReference(transferReference);

        // ERC20.Transfer 事件在 TransferReference 事件之后立即发出
        return transfer(to, amount);
    }

    /**
     * @notice 带有可选转账引用的委托代币转账
     * @dev 需要代币所有者的事先批准。假定底层 `transferFrom` 函数处理
     * 授权和转账逻辑。
     * @param from 授权转账的代币所有者的地址。
     * @param to 代币将发送到的接收者的地址。
     * @param amount 要转移的代币数量。
     * @param transferReference 用于包含转账引用、引用签名或其他相关
     * 参考数据的字节字段。
     * @return 一个布尔值，指示转账是否成功。
     */
    function transferFrom(address from, address to, uint256 amount, bytes calldata transferReference)
        public
        virtual
        returns (bool)
    {
        _logReference(transferReference);

        // ERC20.Transfer 事件在 TransferReference 事件之后立即发出
        return transferFrom(from, to, amount);
    }
}