ERC-7787: 灵魂绑定可降级治理

// SPDX-License-Identifier: CC0-1.0
pragma solidity ^0.8.20;

interface SDG {
  /**
   * @dev 返回投票单位开始衰减之前的宽限期持续时间。此期限固定为 90 天。但可以在派生合约中覆盖。
   * @return 宽限期的持续时间（以秒为单位）。
   */
  function gracePeriod() public view virtual returns (uint256);

  /**
   * @dev 返回投票单位减少的衰减期持续时间。此期限固定为 90 天。但可以在派生合约中覆盖。
   * @return 衰减期的持续时间（以秒为单位）。
   */
  function decayPeriod() public view virtual returns (uint256);

  /**
   * @dev 应由派生合约实现，以返回帐户的当前投票单位。
   * 此函数根据上次更新的时间计算投票单位，并随着时间的推移而衰减。
   * @param account 要检查投票单位的地址。
   * @return 帐户的当前投票单位。
   */
  function getVotes(address account) public view virtual returns (uint256);
}

// SPDX-License-Identifier: CC0-1.0
pragma solidity ^0.8.20;

import { SDG } from "./SDG.sol"; // SDG 实现
import { SOULERC721 } from "./ERC721/SOULERC721.sol"; // Soulbounded ERC721 实现
import { Ownable } from "@openzeppelin/contracts/access/Ownable.sol"; // Oz Ownable 合约

/**
 * @title Valocracy
 * @dev 实现了 SDG 治理模型，其中治理权力会随着时间的推移而衰减，如果未积极维护。
 * 只有 DAO 治理合约（作为所有者）才能铸造新代币或授予额外的治理权力。
 */
contract Valocracy is SDG, SOULERC721, Ownable {
  // 发出事件，当投票单位被更新时
  event VotingUnitsUpdated(address indexed account, uint256 oldVotingUnits, uint256 newVotingUnits);

  // 顺序 ID 和代币总供应量
  uint256 public totalSupply;

  // 地址到其代币 ID 的映射
  mapping(address => uint256) private _tokens;

  /**
   * @param _name ERC721 代币的名称。
   * @param _symbol ERC721 代币的符号。
   */
  constructor(
    string memory _name,
    string memory _symbol
  ) Ownable(_msgSender()) SOULERC721(_name, _symbol) {}

  /**
   * @dev 参见 {IERC721Metadata-tokenURI}。
   * @notice 此函数返回一个静态字符串作为代币 URI。在实际实现中，此
   * 函数应返回一个 URI，该 URI 指向包含有关代币元数据的 JSON 文件。甚至
   * 更好的是，一个动态 SVG，显示代币持有者的治理权力。
   */
  function tokenURI(uint256 tokenId) public pure override returns (string memory) {
    return "自定义图像或动态 NFT，显示治理权力";
  }

  /**
   * @dev 参见 {ISDG-getVotes}。
   */
  function getVotes(address account) public view override returns (uint256) {
    uint256 grantedTime = _lastUpdateOf(account);

    // 如果没有授予投票单位或仍在宽限期内，则返回所有投票单位
    if (grantedTime == 0 || block.timestamp < grantedTime + gracePeriod()) {
      return _votingUnitsOf(account);
    }

    // 计算自宽限期结束以来经过的时间
    uint256 timeSinceGracePeriod = block.timestamp - (grantedTime + gracePeriod());

    // 如果衰减期结束，则返回 0
    if (timeSinceGracePeriod >= decayPeriod()) {
      return 0;
    }

    // 线性衰减：计算衰减期内剩余的投票单位
    uint256 decayPercentage = (timeSinceGracePeriod * 1e18) / decayPeriod(); // 百分比为 18 个小数位
    uint256 remainingVotes = (_votingUnitsOf(account) * (1e18 - decayPercentage)) / 1e18;

    return remainingVotes;
  }

  /**
   * @dev 通过 `amount` 将投票单位授予指定的帐户。只有合约所有者才能
   * 铸造新代币并授予额外的投票单位。如果用户没有代币，则
   * 将为他们铸造一个。
   * @param to 要铸造新代币或授予额外投票单位的地址。
   * @param amount 要伴随代币授予的投票单位数量。
   */
  function grantVotingUnits(address to, uint256 amount) public virtual onlyOwner {
    if (_tokens[to] == 0) {
      _mint(to, ++totalSupply);
      _tokens[to] = totalSupply;
    }

    uint256 votingUnits = getVotes(to);
    _setVotingUnits(to, votingUnits + amount);

    emit VotingUnitsUpdated(to, votingUnits, amount);
  }

  /**
   * @notice 烧毁 ERC721 代币并擦除与代币持有者关联的投票单位。
   * @dev 代币必须存在并且可以由代币持有者或授权实体烧毁。
   * @param tokenId 要烧毁的代币的 ID。
   */
  function burn(uint256 tokenId) public virtual {
    address from = ownerOf(tokenId);
    uint256 votingUnits = getVotes(from);

    _tokens[from] = 0;
    _setVotingUnits(from, 0);
    _burn(tokenId);

    emit VotingUnitsUpdated(from, votingUnits, 0);
  }
}