Michael.W基于Foundry精读Openzeppelin第9期——Multicall.sol

0. 版本

[openzeppelin]：v4.8.3，[forge-std]：v1.5.6

0.1 Multicall.sol

Github: https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.8.3/contracts/utils/Multicall.sol

Multicall库提供了一个multicall(bytes[] calldata data)方法，通过该方法可以由调用者在一笔交易中自由组合调用本合约的各个可外部调用的方法。

1. 目标合约

封装Multicall library成为一个可调用合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/src/utils/MockMulticall.sol

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.0;

import "openzeppelin-contracts/contracts/utils/Multicall.sol";

contract MockMulticall is Multicall {
    uint _number;

    function add(uint i) external {
        _number += i;
    }

    function mul(uint i) external {
        _number *= i;
    }

    function getNumber() external view returns (uint){
        return _number;
    }
}

全部foundry测试合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/test/utils/Multicall.t.sol

2. 代码精读

2.1 multicall(bytes[] calldata)

将每次调用的payload组装进一个数组data，然后利用delegate call本合约。这实现了在一笔交易中自由组合本合约中可外部调用的方法的功能。

    function multicall(bytes[] calldata data) external virtual returns (bytes[] memory results) {
        // 在内存中定义用来存放每次调用的返回值信息的数组results，数组长度与调用次数相同
        results = new bytes[](data.length);
        // 遍历传入的payload数组data
        for (uint256 i = 0; i < data.length; i++) {
            // 携带对应的payload，delegate call本合约。delegate call的结果存放进results中
            results[i] = Address.functionDelegateCall(address(this), data[i]);
        }
        return results;
    }

foundry代码验证

contract MulticallTest is Test {
    MockMulticall mc = new MockMulticall();

    function test_Multicall() external {
        // a batch of 4 function calls:
        // 1. add(5): return ""
        // 2. getNumber(): return 0+5
        // 3. mul(10): return ""
        // 4. getNumber(): return (0+5)*10

        bytes[] memory calldatas = new bytes[](4);
        calldatas[0] = abi.encodeCall(mc.add, (5));
        calldatas[1] = abi.encodeCall(mc.getNumber, ());
        calldatas[2] = abi.encodeCall(mc.mul, (10));
        calldatas[3] = calldatas[1]; // getNumber()

        bytes[] memory results = mc.multicall(calldatas);
        assertEq(results[0], "");
        assertEq(results[1], abi.encode(0 + 5));
        assertEq(results[2], "");
        assertEq(results[3], abi.encode(5 * 10));
    }
}

可见，delegate call一个没有返回值的函数，返回值为空。

ps:\ 本人热爱图灵，热爱中本聪，热爱V神。 以下是我个人的公众号，如果有技术问题可以关注我的公众号来跟我交流。 同时我也会在这个公众号上每周更新我的原创文章，喜欢的小伙伴或者老伙计可以支持一下！ 如果需要转发，麻烦注明作者。十分感谢！

公众号名称：后现代泼痞浪漫主义奠基人