Sui Move 合约升级与权限定制

Nigdle
发布于 2024-03-25 22:36
阅读 1195

Sui Move 合约升级与权限定制

# 一：猜数设计

让我们来设计一个简单的猜数程序，用户猜测一个数字并传入函数，判断与程序随机而成的数字是否相同，如果相同就给予一定奖励。

这里的奖励可以是链上流通的货币或是其它有价值的虚拟物品，不过作为一篇适合 $\mathit {Sui\ Move}$ 初学者的简单用例，直接牵扯到高昂物品似乎有所不妥，所以这里的奖励就用一个整型的 $\mathit {prize}$ 来表示，将含有奖金的 $\mathit {object}$ 发送给猜中数字的玩家，以此来作为激励手段。

同时，我们还可以用 $\mathit {Events}$ 来记录链上发生的重大事件。在这个例子里，重大事件无疑就是 $\mathit {Winner}$ 了，我们可以用事件来记录胜者玩家的地址，为了让数据有一定的分析价值，还可以记录到这一次猜中数之前的所有玩家的尝试总数。

那么，根据分析，我们可以用三个 $\mathit {struct}$ 来存储这些信息。

```move
struct Count has key {
    id: UID,
    total: u64,
}

struct Prize has key {
    id: UID,
    prize: u8,
}

struct GuessEvent has copy, drop {
    total_count: u64,
    final_winner: address,
}
```

- $\mathit {Count}$ 会作为一个共享对象，让所有玩家都可以访问并修改，其中的 $\mathit {total}$ 将存储一共的尝试猜数的次数，直到猜中时清零重置。
- $\mathit {Prize}$ 直到被猜中数时才会被创建，同时被发送给此次交易的发起者，也就是猜中数字的玩家，其中的 $\mathit {prize}$ 可以简单设定为猜中的数等值的金额，由于猜数的范围不能太大，不妨就以 $[\text 0,\ \text {10}]$ 这个闭区间为前置条件。
- $\mathit {GuessEvent}$ 是定义的一个事件，我们只关心事件当中的值，同时让它在作用域结束时自我消亡，所以设定了 $\mathit {copy},\ \mathit {drop}$ 这两个能力。 触发事件时只需要使用`sui::event::emit(<ObjectEvent>);` 而交易产生的事件详情可以在 [$\mathit {Sui\ explorer}$](https://suiexplorer.com/) 中的 $\mathit {Events}$ 标签页查看。

根据上述分析，我们可以很轻松地编写三个函数。

```move
fun init(ctx: &mut TxContext) {
    let count = Count {
        id: object::new(ctx),
        total: 0,
    };
    transfer::share_object(count);
}

fun send_prize(count: u64, prize: u8, ctx: &mut TxContext) {
    transfer::transfer(Prize {
        id: object::new(ctx),
        prize,
    }, tx_context::sender(ctx));

event::emit(GuessEvent {
        total_count: count,
        final_winner: tx_context::sender(ctx),
    });
}

public entry fun guess_between_zero_and_hundred(count: &mut Count, number: u8, clock: &Clock, ctx: &mut TxContext) {
    let des_number = ((clock::timestamp_ms(clock) % 11) as u8);
    if (number == des_number) {
        send_prize(count.total, number, ctx);
        count.total = 0;
    } else {
        count.total = count.total + 1;
    }
}
```

- $\mathit {init}$ 函数只会在发布时被调用一次，用来创建 $\mathit {Count}$ 并将其共享再好不过。
- $\mathit {send\_prize}$ 函数是在数字被猜中时调用的，作用是将奖励 $\mathit {Prize}$ 发送给中奖者，同时触发一个事件。
- $\mathit {entry}$ 函数是指在交易过程中能够被直接调用的，它不应该有返回值，因为即使有也没什么作用，入口函数被不被 $\mathit {public}$ 修饰的区别在于能否被其它模块调用，以及合约升级时能否被更改等。 $\mathit {guess\_between\_zero\_and\_hundred}$ 函数名就暗示了猜数的范围（一开始是想 [$\text 0,\ \text {100}$] 的，但一想到测试时会测死，就缩小到了 $\text 10$，但函数名忘改成 $\mathit {ten}$ 了┭┮﹏┭┮），其中有个参数是 $\mathit {Clock}$，我们可以用它来获得时间戳，用这个时间戳来转化成目标数字。 这种“随机”方式其实并不安全，因为这个值是可控的，真实的交易环境也不会如此草率，不过这并不如此篇的重点，也就不再赘述。 $\mathit {timestamp\_ms}$ 得到的值是 $\mathit u\text{64}$ 类型的，我们可以用 $\mathit {as}$ 关键词简单地将其转化成 $\mathit u\text 8$。（这里只是为了顺带提一句 $\mathit {as}$ 的作用才设定成这个类型的整数的，前篇里还提到了它可以为导入的模块取别名，如果忘记了的可以去翻一翻）

好，至此，简单的猜数就设计完毕，但是别忘了这一篇章的主题**合约升级与权限定制**！

# 二：修改代码以支持版本更迭

发布的合约 $\mathit {package}$ 是不可变的 $\mathit {object}$，不可撤回也无法修改。智能合约升级的本质是在新的地址上重新发布新的合约，并且把旧版合约的数据迁移过去。

当然，合约升级并不意味着可以对代码进行肆无忌惮地修改，需要满足如下几条规则：

- 现有的 $\mathit {public}$ 函数的输入输出参数格式保持不变
- 可以添加新的 $\mathit {struct}$ 和函数
- 可以给现有的 $\mathit {struct}$ 添加新的能力
- 可以把现有函数中对泛型参数的约束去掉
- 可以改变函数的实现
- 可以修改非 $\mathit {public}$ 函数的输入输出参数格式，包括 $\mathit {friend}$ 和 $\mathit {entry}$ 函数
- 可以让非 $\mathit {public}$ 函数变为 $\mathit {public}$ 函数

除此之外还需要注意的是，$\mathit {init}$ 函数只会在第一次发布合约时执行，后续合约升级时不会被重复执行。同时，如果你的 $\mathit {package}$ 依赖了一个外部的 $\mathit {package}$，你需要手动把它指向新依赖的合约地址，这一过程在升级合约时不会自动进行。

根据上述内容，我们来思考，想要让一份合约支持后续迭代升级，需要添加一些什么？

1. $\mathit {VERSION}$，定义一个常量来表示版本号。因为升级合约并不会将旧的合约地址销毁，所以我们需要明确版本，非对应版本的调用都不应执行。
2. 共享对象 $\mathit {Count}$ 中添加版本号字段，用来判断数据是否已经迁移。（还没来得及迁移的数据，可以接受旧的对应版本的合约的函数调用，但它不能接受新的）
3. 为了实现数据迁移，自然也就需要添加一个函数来实现这一点，在这个例子当中的主要作用就是更新 $\mathit {Count}$ 对象当中的版本号字段。
4. 相关的升级迭代的操作应该都只授权给发布者，其他人不该有权限调用。为了达到这一目的，不妨在共享对象当中再添加一个字段，用来存储发布者的 $\mathit {ID}$。我们已经知道，$\mathit {init}$ 只会在第一次合约发布时被调用，当时的 $\mathit {TxContext}$ 一定是发布者，那么该阶段存储进去的 $\mathit {ID}$ 也将是发布者的。 那么如何在调用数据迁移时传入这个 $\mathit {ID}$？不如再定义一个 $\mathit {struct}$，拥有 $\mathit {key}$ 能力，将其交给我们的发布者，届时只需要传入该 $\mathit {object}$ 的地址即可作为凭据。
5. 至于怎么在版本不对应，或者非授权操作情况下中断并退出，可以使用`assert!(<bool>, <error code>)`，这在前面的篇章当中已有涉及。为了适应更多变的情况，同时提高代码的可读性，可以将 $\mathit {error\ code}$ 定义成一个常量再作为参数传入。

修改并整合后的代码如下：

```move
module guess_number::guess_number {
    use sui::object::{Self, ID, UID};
    use sui::tx_context::{Self, TxContext};
    use sui::transfer;
    use sui::clock::{Self, Clock};
    use sui::event;

const VERSION: u64 = 1;

const ENOTVERSION: u64 = 0;
    const ENOTADMIN: u64 = 1;
    const ENOTUPGRADE: u64 = 2;

struct Count has key {
        id: UID,
        version: u64,
        admin: ID,
        total: u64,
    }

struct AdminCap has key {
        id: UID,
    }

struct Prize has key {
        id: UID,
        prize: u8,
    }

struct GuessEvent has copy, drop {
        total_count: u64,
        final_winner: address,
    }

fun init(ctx: &mut TxContext) {
        let admin_cap = AdminCap {id: object::new(ctx)};

let count = Count {
            id: object::new(ctx),
            version: VERSION,
            admin: object::id(&admin_cap),
            total: 0,
        };

transfer::transfer(admin_cap, tx_context::sender(ctx));
        transfer::share_object(count);
    }

fun send_prize(count: u64, prize: u8, ctx: &mut TxContext) {
        transfer::transfer(Prize {
            id: object::new(ctx),
            prize,
        }, tx_context::sender(ctx));

event::emit(GuessEvent {
            total_count: count,
            final_winner: tx_context::sender(ctx),
        });
    }

public entry fun guess_between_zero_and_hundred(count: &mut Count, number: u8, clock: &Clock, ctx: &mut TxContext) {
        assert!(count.version == VERSION, ENOTVERSION);

let des_number = ((clock::timestamp_ms(clock) % 11) as u8);
        if (number == des_number) {
            send_prize(count.total, number, ctx);
            count.total = 0;
        } else {
            count.total = count.total + 1;
        }
    }

entry fun migrate(count: &mut Count, admin_cap: &AdminCap) {
        assert!(count.admin == object::id(admin_cap), ENOTADMIN);
        assert!(count.version != VERSION, ENOTUPGRADE);

count.version = VERSION;
    }
}
```

别着急，配置文件 $\mathit {Move.toml}$ 也需要做更改，主要是在 [$\mathit {package}$] 下添加版本号。（这里的 $\mathit {version}$ 和代码中的可以不一致）

```
[package]
name = "guess_number"
version = "0.0.0"

[addresses]
guess_number = "0x0"
```

# 三：原始合约发布

```
sui move build
sui client publish --gas-budget 100000000
```

发布成功后在信息里找到跟 $\mathit {package}$ 相关的： ![Object Changes.png](https://img.learnblockchain.cn/attachments/2024/03/JtShr4Ha66018b05819f7.png)

所发布的包的 $\mathit {PackageID}$，以及 $\mathit {AdminCap},\ \mathit {Count},\ \mathit {UpgradeCap}$ 的 $\mathit {PackageID}$ 都是后续会用到的，可以用 $\mathit {export}$ 来赋予一个别名，方便取用。

```
export PACKAGE_ID=0x628f33fcf96ebc82f275bddb7ad927b0e260e989f2131e0e1dc844ab931b57f5
export ADMIN_CAP=0x2160bdabbe0321d418cd6572ab24092554c3fbea0b5f24fd32295eaf2b8fa63a
export COUNT=0x415f0255873919cc68c217a715454b54537ad3c0677b7d3b925c777131dbf19c
export UPGRADE_CAP=0x57ae075216a7996c944af979a7fe8057f6d1b2165055cdddce9f7898579fc8cd
```

接下来，我们就可以用下述命令来猜数了： `sui client call --package $PACKAGE_ID --module guess_number --function guess_between_zero_and_hundred --args $COUNT 6 0x6 --gas-budget 100000000` 其中`0x6`作为 $\mathit {Clock}$ 参数的地址传递。

通过`sui client object $COUNT`得到的信息可以发现，字段 $\mathit {total}$ 的值为 $\text 1$，说明一共尝试了一次没有成功，此时，重复猜数，直到猜中。

尝试了好几次（永远的$6$），终于在猜数后得到的信息里，$\mathit {Object\ Changes}$ 看到了它新建了一个 $\mathit {Prize}$ 对象，它的拥有者是玩家本人。分别查看 $\mathit {Count}$ 和 $\mathit {Prize}$ 当中存储的内容，如下图所示，发现符合预期。 ![Count and Prize.png](https://img.learnblockchain.cn/attachments/2024/03/opklobt866018b12b801a.png)

别忘了事件，除了本文最开始提到的查看方式，其实在执行猜中数的那一次给出的信息当中就有相应的信息： ![Event.png](https://img.learnblockchain.cn/attachments/2024/03/4fljPSCD66018b1b7b7a5.png)

# 四：合约升级

在上述代价的基础上，首先来思考，除了功能上的升级之外，需要修改什么？

1. $\mathit {VERSION}$ 作为版本的标志，势必要扩大。
2. $\mathit {Move.toml}$ 中 [$\mathit {package}$] 中的 $\mathit {version}$ 也需要更改，同时添加新的一行`published-at = "<ORIGINAL-PACKAGE-ID>"`，用来标注旧合约地址是哪儿。如果不知道这个信息，又何来数据迁移和升级。

```
// guess_number.move
const VERSION: u64 = 2;

// Move.toml
[package]
name = "guess_number"
version = "0.0.1"
published-at = "0x628f33fcf96ebc82f275bddb7ad927b0e260e989f2131e0e1dc844ab931b57f5" //这里需要替换成你们自己的旧合约地址
```

接下来，我们来思考哪些功能存在优化的空间？

真实情况下，奖励的东西应该更加吸引人，这样才能诱使人与之进行交易（猜数），所以我们扩大 $\mathit {prize}$，让它等于猜中的那个数乘上一共所猜的次数的十倍，为了不超过 $\mathit u \text 8$ 的数据范围，还需要跟 $\text {255}$ 取个最小值。

本次示例就以这一点为代表进行，只要是符合之前所列举的修改规则的都是可以的，你可以自由发挥(๑•̀ㅂ•́)و✧

经过优化后的代码如下：

const VERSION: u64 = 2;