Michael.W基于Foundry精读Openzeppelin第5期——Counters.sol

0. 版本

[openzeppelin]：v4.8.3，[forge-std]：v1.5.6

0.1 Counters.sol

Github: https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.8.3/contracts/utils/Counters.sol

将uint256封装了成一个计数器，可做自增1，自减1或重置操作。一般用该库可以追踪一个mapping中元素个数，ERC721的token id和统计请求次数等。

1. 目标合约

封装Counters library成为一个可调用合约:

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/src/utils/MockCounters.sol

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.0;

import "openzeppelin-contracts/contracts/utils/Counters.sol";

contract MockCounters {
    // Counters库中定义的Counter结构体可使用Counters库中的库函数
    using Counters for Counters.Counter;

    Counters.Counter _counter;

    function current() external view returns (uint){
        return _counter.current();
    }

    function increment() external {
        _counter.increment();
    }

    function decrement() external {
        _counter.decrement();
    }

    function reset() external {
        _counter.reset();
    }
}

全部foundry测试合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/test/utils/Counters.t.sol

2. 代码精读

2.1 结构体Counter

在Counters库内定义的一个结构体。该结构体其实就是一个uint256的封装，在主合约中定义一个Counters.Counter类型的storage变量（其中value初始为0），配合本库的库函数使用。

代码解读

    struct Counter {
        uint256 _value;
    }

注：出于设计安全考虑，在你的合约中定义的storage Counter的所有读写都要限定在使用本库函数。在主合约中直接通过storage指针修改storage Counter的_value值会打破本库的安全性。

2.2 current(Counter storage)

返回计数器的当前值。

代码解读

    function current(Counter storage counter) internal view returns (uint256) {
        // 返回计数器结构体中的_value值
        return counter._value;
    }

2.3 increment(Counter storage)

计数器自增1。

代码解读

    function increment(Counter storage counter) internal {
        // 取消solidity 0.8中对数学运算的溢出检查
        unchecked {
            // 计数器中的_value自增1
            counter._value += 1;
        }
    }

为什么可以取消溢出检查？我认为计数器每次都是自增1，所以只有当counter._value为$2^{256}-1$时才会正溢出（这是个极小概率的事件）。而且做数学运算的溢出检查是要消耗gas的，取消检查可达到节约gas的目的。

foundry代码验证

    function test_Increment() external {
        assertEq(0, mc.current());
        mc.increment();
        assertEq(1, mc.current());
        mc.increment();
        assertEq(2, mc.current());
    }

2.4 decrement(Counter storage)

计数器自减1。

代码解读

    function decrement(Counter storage counter) internal {
        uint256 value = counter._value;
        // 计数器value值为0时报错，因为自减后会负向溢出
        require(value > 0, "Counter: decrement overflow");
        // 取消solidity 0.8中对数学运算的溢出检查
        unchecked {
            // 计数器中的_value自减1
            counter._value = value - 1;
        }
    }

注：其实上面的require(value>0, ...)和unchecked{...}，就等同于一个做运算溢出检查的counter._value-=1。

foundry代码验证

    function test_Decrement() external {
        mc.increment();
        assertEq(1, mc.current());
        mc.decrement();
        assertEq(0, mc.current());
        // overflow
        vm.expectRevert("Counter: decrement overflow");
        mc.decrement();
    }

2.5 reset(Counter storage)

重置计数器，即计数器归0。

代码解读

    function reset(Counter storage counter) internal {
        // 计数器value清0
        counter._value = 0;
    }

foundry代码验证

    function test_Reset() external {
        mc.increment();
        mc.increment();
        assertEq(2, mc.current());
        mc.reset();
        assertEq(0, mc.current());
    }

ps:\ 本人热爱图灵，热爱中本聪，热爱V神。 以下是我个人的公众号，如果有技术问题可以关注我的公众号来跟我交流。 同时我也会在这个公众号上每周更新我的原创文章，喜欢的小伙伴或者老伙计可以支持一下！ 如果需要转发，麻烦注明作者。十分感谢！

公众号名称：后现代泼痞浪漫主义奠基人