0. 版本

[openzeppelin]：v4.8.3，[forge-std]：v1.5.6

0.1 ERC20VotesComp.sol

Github: https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.8.3/contracts/token/ERC20/extensions/ERC20VotesComp.sol

ERC20VotesComp库是专门适配Compound投票和委托的ERC20拓展库。本库可对接Compound的接口，同时也存在缺点（总发行量上限为2^96 - 1）。如果业务上确定需要兼容Compound（如：要在Compound Governor Alpha或Bravo中使用该ERC20），那必须弄清楚总发行量上限是否符合业务需求。否则可使用ERC20Votes库。

注：ERC20Votes库详解见：https://learnblockchain.cn/article/7616

1. 目标合约

继承ERC20VotesComp合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/src/token/ERC20/extensions/MockERC20VotesComp.sol

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.0;

import "openzeppelin-contracts/contracts/token/ERC20/extensions/ERC20VotesComp.sol";

contract MockERC20VotesComp is ERC20VotesComp {
    constructor(
        string memory name,
        string memory symbol
    )
    ERC20Permit(name)
    ERC20(name, symbol)
    {}

    function maxSupply() external view returns (uint224){
        return _maxSupply();
    }

    function mint(address account, uint amount) external {
        _mint(account, amount);
    }
}

全部foundry测试合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/test/token/ERC20/extensions/ERC20VotesComp.t.sol

2. 代码精读

2.1 _maxSupply() internal

获取本token的最大供应量。

需要注意的是：ERC20VotesComp库支持的最大供应量为2^96-1，而ERC20Votes库为2^224-1。

    function _maxSupply() internal view virtual override returns (uint224) {
        // 返回2^96-1
        return type(uint96).max;
    }

foundry代码验证：

contract ERC20VotesTest is Test {
    MockERC20VotesComp private _testing = new MockERC20VotesComp("test name", "test symbol");

    function test_MaxSupply() external {
        assertEq(_testing.maxSupply(), type(uint96).max);
    }
}

2.2 getCurrentVotes(address account)

获取地址account当前得到的总票数。本方法是对ERC20Votes.getVotes()的封装，返回值类型为uint96。

    function getCurrentVotes(address account) external view virtual returns (uint96) {
        // 调用ERC20Votes.getVotes()并将返回值从uint256安全转成uint96（如果转换过程发生溢出会revert）
        return SafeCast.toUint96(getVotes(account));
    }

foundry代码验证：

contract ERC20VotesTest is Test {
    MockERC20VotesComp private _testing = new MockERC20VotesComp("test name", "test symbol");
    address private user1 = address(1);

    function test_GetCurrentVotes() external {
        _testing.mint(address(this), 100);
        assertEq(_testing.getCurrentVotes(user1), 0);
        _testing.delegate(user1);
        assertEq(_testing.getCurrentVotes(user1), 100);

        _testing.transfer(user1, 1);
        assertEq(_testing.getCurrentVotes(user1), 100 - 1);
        _testing.transfer(user1, 2);
        assertEq(_testing.getCurrentVotes(user1), 100 - 1 - 2);
        _testing.transfer(user1, 3);
        assertEq(_testing.getCurrentVotes(user1), 100 - 1 - 2 - 3);
        _testing.transfer(user1, 4);
        assertEq(_testing.getCurrentVotes(user1), 100 - 1 - 2 - 3 - 4);
        _testing.transfer(user1, 5);
        assertEq(_testing.getCurrentVotes(user1), 100 - 1 - 2 - 3 - 4 - 5);
    }
}

2.3 getPriorVotes(address account, uint256 blockNumber)

获取地址account在blockNumber区块高度时得到的总票数。本方法是对ERC20Votes.getPastVotes()的封装，返回值类型为uint96。

    function getPriorVotes(address account, uint256 blockNumber) external view virtual returns (uint96) {
        // 调用ERC20Votes.getPastVotes()并将返回值从uint256安全转成uint96（如果转换过程发生溢出会revert）
        return SafeCast.toUint96(getPastVotes(account, blockNumber));
    }

foundry代码验证：

contract ERC20VotesTest is Test {
    MockERC20VotesComp private _testing = new MockERC20VotesComp("test name", "test symbol");
    address private user1 = address(1);

    function test_GetPriorVotes() external {
        // 6 Checkpoints of user1:
        //       block             votes             index
        //          2                10                0
        //          3                15                1
        //          6                19                2
        //          10               20                3
        //          11               23                4
        //          13               31                5

        _testing.delegate(user1);
        vm.roll(2);
        _testing.mint(address(this), 10);
        vm.roll(3);
        _testing.mint(address(this), 15 - 10);
        vm.roll(6);
        _testing.mint(address(this), 19 - 15);
        vm.roll(10);
        _testing.mint(address(this), 20 - 19);
        vm.roll(11);
        _testing.mint(address(this), 23 - 20);
        vm.roll(13);
        _testing.mint(address(this), 31 - 23);
        vm.roll(20);

        assertEq(_testing.getPriorVotes(user1, 1), 0);
        assertEq(_testing.getPriorVotes(user1, 2), 10);
        assertEq(_testing.getPriorVotes(user1, 3), 15);
        assertEq(_testing.getPriorVotes(user1, 5), 15);
        assertEq(_testing.getPriorVotes(user1, 6), 19);
        assertEq(_testing.getPriorVotes(user1, 7), 19);
        assertEq(_testing.getPriorVotes(user1, 9), 19);
        assertEq(_testing.getPriorVotes(user1, 10), 20);
        assertEq(_testing.getPriorVotes(user1, 11), 23);
        assertEq(_testing.getPriorVotes(user1, 12), 23);
        assertEq(_testing.getPriorVotes(user1, 13), 31);
        assertEq(_testing.getPriorVotes(user1, 19), 31);

        // revert if block not mined
        vm.expectRevert("ERC20Votes: block not yet mined");
        _testing.getPriorVotes(user1, 20);
    }
}

ps: 本人热爱图灵，热爱中本聪，热爱V神。 以下是我个人的公众号，如果有技术问题可以关注我的公众号来跟我交流。 同时我也会在这个公众号上每周更新我的原创文章，喜欢的小伙伴或者老伙计可以支持一下！ 如果需要转发，麻烦注明作者。十分感谢！

公众号名称：后现代泼痞浪漫主义奠基人