Michael.W基于Foundry精读Openzeppelin第15期——SignedMath.sol

0. 版本

[openzeppelin]：v4.8.3，[forge-std]：v1.5.6

0.1 SignedMath.sol

Github: https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.8.3/contracts/utils/math/SignedMath.sol

SignedMath库提供了solidity中尚未内置的标准有符号数的数学运算方法。

1. 目标合约

封装SignedMath library成为一个可调用合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/src/utils/math/MockSignedMath.sol

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.0;

import "openzeppelin-contracts/contracts/utils/math/SignedMath.sol";

contract MockSignedMath {
    using SignedMath for int;

    function max(int a, int b) external pure returns (int) {
        return a.max(b);
    }

    function min(int a, int b) external pure returns (int) {
        return a.min(b);
    }

    function average(int a, int b) external pure returns (int){
        return a.average(b);
    }

    function abs(int n) external pure returns (uint) {
        return n.abs();
    }
}

全部foundry测试合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/test/utils/math/SignedMath.t.sol

2. 代码精读

2.1 max(int256 a, int256 b) && min(int256 a, int256 b)

• max(int256 a, int256 b)：求两个有符号数中的最大值；
• min(int256 a, int256 b)：求两个有符号数中的最小值。

    function max(int256 a, int256 b) internal pure returns (int256) {
        // 通过三元运算符来求二者中的最大值
        return a > b ? a : b;
    }

    function min(int256 a, int256 b) internal pure returns (int256) {
        // 通过三元运算符来求二者中的最小值
        return a < b ? a : b;
    }

foundry代码验证

contract SignedMathTest is Test {
    MockSignedMath msm = new MockSignedMath();

    function test_Max() external {
        assertEq(msm.max(1, 2), 2);
        assertEq(msm.max(- 1, - 2), - 1);
        assertEq(msm.max(- 1, 1), 1);
        assertEq(msm.max(- 1, 0), 0);
        assertEq(msm.max(1, 0), 1);
    }

    function test_Min() external {
        assertEq(msm.min(1, 2), 1);
        assertEq(msm.min(- 1, - 2), - 2);
        assertEq(msm.min(- 1, 1), - 1);
        assertEq(msm.min(- 1, 0), - 1);
        assertEq(msm.min(1, 0), 0);
    }
}

2.2 average(int256 a, int256 b)

求两个有符号整数的平均值，结果向零取整。

注：对比传统解法(a+b)/2，本方法不会在a和b足够大或足够小时产生溢出。

    function average(int256 a, int256 b) internal pure returns (int256) {
        // 具体位运算的数学依据参见书籍《Hacker's Delight》：https://baike.baidu.com/item/Hacker%27s%20Delight/6927658?fr=ge_ala
        // x为a&b与(a^b)/2的和。为两个uint256求均值的方法。详情见：https://learnblockchain.cn/article/6191中的2.4——average(uint256, uint256)
        int256 x = (a & b) + ((a ^ b) >> 1);
        // uint256(x) >> 255：将前面计算得出的x转成uint256后右移255位得到符号位。即如果x为负数则为1，如果未非负数则为0。
        // 将上述符号位转换成int256，并与a^b的结果做与运算。返回x与上述运算结果的和（即两个有符号数的均值）
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

foundry代码验证

contract SignedMathTest is Test {
    MockSignedMath msm = new MockSignedMath();

    function test_Average() external {
        assertEq(msm.average(2, 4), 3);
        assertEq(msm.average(2, 3), 2);
        assertEq(msm.average(type(int).max, type(int).max - 2), type(int).max - 1);
        assertEq(msm.average(type(int).min, type(int).min + 2), type(int).min + 1);
    }
}

2.3 abs(int256 n)

求一个int256的绝对值

    function abs(int256 n) internal pure returns (uint256) {
        // 关闭solidity 0.8的整数运算溢出检查。为了当n为type(int).min时不发生溢出错误
        unchecked {
            // 如果n不是负数，返回uint256(n)。否则返回uint256(-n)
            return uint256(n >= 0 ? n : -n);
        }
    }

foundry代码验证

contract SignedMathTest is Test {
    MockSignedMath msm = new MockSignedMath();

    function test_Abs() external {
        assertEq(msm.abs(0), 0);
        assertEq(msm.abs(- 1), 1);
        assertEq(msm.abs(1), 1);
        // int256的最大正数的二进制为0+255个1
        assertEq(msm.abs(type(int).max), (1 << 255) - 1);
        // int256的最小负数的二进制为其最大正数+1，即1+255个0
        assertEq(msm.abs(type(int).min), 1 << 255);
    }
}

ps:\ 本人热爱图灵，热爱中本聪，热爱V神。 以下是我个人的公众号，如果有技术问题可以关注我的公众号来跟我交流。 同时我也会在这个公众号上每周更新我的原创文章，喜欢的小伙伴或者老伙计可以支持一下！ 如果需要转发，麻烦注明作者。十分感谢！

公众号名称：后现代泼痞浪漫主义奠基人